使用已发布的 Moo API 在 Moo 中动态修改方法

Question

我正在尝试坚持已发布的API来动态修改Moo中的方法，还没有想出一个通用的解决方案。

首先，一些代码：

package R1 {
    use Moo::Role;
    sub r1 { say __PACKAGE__ }
}

package C1 {
    use Moo;
    sub c1 { say __PACKAGE__ }
}

use Scalar::Util qw[ blessed ];
use Moo::Role ();

my $c = C1->new;
Moo::Role->apply_roles_to_object( $c, 'R1' );

角色应用程序将说明一种方法的失败。

我尝试了两种方法。

第一次使用Class::Method::Modifiers：

use Class::Method::Modifiers qw[ install_modifier ];
install_modifier( blessed( $c ), 
                  before => r1 =>
                  sub { say "BEFORE r1" }
                );
$c->r1;

并且工作正常：

% perl test.pl
BEFORE r1
R1

Moo 的内部_install_modifier 子程序的代码非常相似，但也执行了额外的Moo 特定动作，因此这种方法并不完全等效。

我尝试的下一个方法是直接使用$c 可用的before 修饰符，从而获得额外的Moo 特殊酱汁：

$c->can('before')->( r1 => sub { say "BEFORE r1" } );
$c->r1;

但是……

% perl test.pl
The method 'r1' is not found in the inheritance hierarchy for class C1 at [...]/lib/site_perl/5.28.0/Class/Method/Modifiers.pm line 42.
        Class::Method::Modifiers::install_modifier("C1", "before", "r1") called at /[...]/lib/site_perl/5.28.0/Moo/_Utils.pm line 44
        Moo::_Utils::_install_modifier("C1", "before", "r1", CODE(0x5590bb800360)) called at [...]/lib/site_perl/5.28.0/Moo.pm line 84
        Moo::before("r1", CODE(0x5590bb800360)) called at test.pl line 25

似乎为原始C1 类生成了修饰符，并且在应用R1 角色时未更新。以下令人震惊的黑客“修复”了：

use Import::Into;
Moo->import::into( blessed $c );

$c->can('before')->( r1 => sub { say "BEFORE r1" } );
$c->r1;

导致：

% perl test.pl
BEFORE r1
R1

那么，有没有一种方法可以仅使用已发布的Moo API 来实现我的目标？

谢谢！

Answer 1

您可以通过仅应用另一个角色来修改方法（它甚至不必是 Moo::Role，除非您正在处理属性）：

use Role::Tiny;
before r1 => sub { say "BEFORE r1" };

只要确保在构成 r1 方法的那个角色之后应用这个角色，或者在角色中包含一个虚拟的 sub r1 {}（如果已经存在，它将被忽略）。