我无法将文本文件放入数组，然后对数组进行排序

Question

我需要将保存的文本文件读入一个数组，然后对其进行数字排序。这相当困难，因为文本文件是：

10 First name:bob
30 first name:sam

等等。它不是这样排序的，它以分数“名字”&名字的结构保存在文本文件中。我必须对它进行排序，从最高到最低。我试过sort.array。但这仅用于按字母顺序对只有单词的数组进行排序。我尝试了其他过程，但它们似乎不起作用。有人能帮我吗。谢谢

Answer 1

使用 LINQ：

    Dim DataFileName As String = "C:\Users\Mike\Documents\Data.txt"
    Dim SortedByScore = From line In System.IO.File.ReadLines(DataFileName)
                        Let score = CInt(line.Split(" ")(0))
                        Order By score Descending
                        Select line
    For Each line As String In SortedByScore
        Debug.Print(line.ToString)
    Next

将 Array.Sort() 与比较器一起使用：

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim DataFileName As String = "C:\Users\Mike\Documents\Data.txt"
    Dim Lines() As String = System.IO.File.ReadAllLines(DataFileName)
    Array.Sort(Lines, AddressOf SortByScore)
    For Each line As String In Lines
        Debug.Print(line.ToString)
    Next
End Sub

对于问题中指定的原始格式为：10 First name:bob

Private Function SortByScore(ByVal x As Object, ByVal y As Object) As Integer
    Dim valuesX() As String = x.ToString.Split(" ")
    Dim valuesY() As String = y.ToString.Split(" ")
    Return CInt(valuesY(0)).CompareTo(CInt(valuesX(0)))
End Function

如果格式其实是：bob{vbTab}score :10，那么试试：

Private Function SortByScore(ByVal x As Object, ByVal y As Object) As Integer
    Dim valuesX() As String = x.ToString.Split(":")
    Dim valuesY() As String = y.ToString.Split(":")
    Return CInt(valuesY(1)).CompareTo(CInt(valuesX(1)))
End Function