如何在perl中对包含两个数字的字符串数组进行排序？答案

【问题标题】：How to sort an array of strings containing two numbers in perl?如何在perl中对包含两个数字的字符串数组进行排序？
【发布时间】：2015-07-03 21:02:40
【问题描述】：

我有以下字符串数组：

Expt5_Expt12
Expt5_Expt1
Expt12_Expt2
Expt11_Expt8
Expt1_Expt2
Expt10_Expt1
Expt10_Expt4
Expt11_Expt1

我想按第一个数字对这些字符串进行排序，然后按第二个数字对这些字符串进行排序，这样我就有了一个这样的列表：

Expt1_Expt2
Expt5_Expt1
Expt5_Expt12
Expt10_Expt1
Expt10_Expt4
Expt11_Expt1
Expt11_Expt8
Expt12_Expt2

我只找到了仅按第一个数字或第二个数字排序的解决方案。我用正则表达式和排序函数尝试了一些东西，但没有找到解决方案。

【问题讨论】：

您应该向我们展示您尝试过的内容，以便我们帮助您解决问题。

标签： arrays string perl sorting numbers

【解决方案1】：

按功能排序真的很容易。该函数必须返回 -1、0 或 1，具体取决于 $a 和 $b 是在之前还是之后。（如 cmets 中所述 - 它可以是任何正值或负值 - 关键是元素是在彼此之前还是之后）。

$a 和 $b 是专门用于 perl 和排序的“特殊”变量。因此它们不需要被声明，并且对于代码中的其他内容使用是一个真的个坏主意。但是，谁使用单字母变量呢？

所以你的价值观：

#!/usr/bin/env perl
use strict;
use warnings;

sub custom_sort {
   my ( $a1, $a2 ) = ( $a =~ m/(\d+)/g );   #extract the numeric elements
   my ( $b1, $b2 ) = ( $b =~ m/(\d+)/g );

   return ( $a1 <=> $b1     #return the result of this comparison
         || $a2 <=> $b2 );  #unless it's zero, then we return the result of this.
}


my @list = <DATA>;    
print sort custom_sort @list; 

__DATA__
Expt5_Expt12
Expt5_Expt1
Expt12_Expt2
Expt11_Expt8
Expt1_Expt2
Expt10_Expt1
Expt10_Expt4
Expt11_Expt1

你可以让这个更简洁，但本质是这样的：

提取第一个和第二个值。
然后使用|| 运算符 - 如果$a1 <=> $b1 为零，它会计算表达式的第二部分。
<=> 是一个“小于、等于、大于”运算符，它根据数值比较返回 -1、0 或 1。对于字符串，您可以使用cmp 来做同样的事情。

（如果您希望调试这种排序在每次比较时如何“工作”，您可以打印这些，如果您正在做一些复杂的事情，这真的很方便）

【讨论】：

感谢您的快速回答。它工作得很好，我学到了一些新东西。
小问题：sort 不关心块返回的具体值。它关心它与 0 的关系。

【解决方案2】：

这与其他人发布的解决方案大致相同，但使用map 使其更加简洁

use strict;
use warnings;

my @data = <DATA>;

print sort {
    my @ab = map [ /\d+/g ], $a, $b;
    $ab[0][0] <=> $ab[1][0] or $ab[0][1] <=> $ab[1][1];
} @data;

__DATA__
Expt5_Expt12
Expt5_Expt1
Expt12_Expt2
Expt11_Expt8
Expt1_Expt2
Expt10_Expt1
Expt10_Expt4
Expt11_Expt1

输出

Expt1_Expt2
Expt5_Expt1
Expt5_Expt12
Expt10_Expt1
Expt10_Expt4
Expt11_Expt1
Expt11_Expt8
Expt12_Expt2

【讨论】：

【解决方案3】：

使用Sort::Key::Multi；

use Sort::Key::Multi qw(i2_keysort); #i2 means two integer keys

my @sorted = i2_keysort { /(\d+)\D+(\d+)/ } @data;

【讨论】：