如何确定哪个 URLLoader 以编程方式失败？

Question

我正在开发一个使用 URLLoader 从远程服务器获取信息的 Flash 应用程序。我有一个函数可以根据产品 ID 创建信息请求。出现错误时，我想回退到备用 URL，但要创建备用 URL，我需要知道产品 ID。确定哪个 URLLoader 失败（以及哪个产品请求失败）以便我可以重新生成新 URL 的最佳方法是什么？

我的功能如下：

function loadData(productID:String):URLLoader {
  var productURL:URLRequest = new URLRequest("/path/to/product/" + productID);
  var dataLoader:URLLoader = new URLLoader();

  dataLoader.addEventListener(Event.COMPLETE, parseData);
  dataLoader.addEventListener(IOErrorEvent.IO_ERROR, handleDataError);
  dataLoader.load(productURL);

  return dataLoader;
}

function handleDataError(e:IOErrorEvent) {
  var productID:String = ???;
  var altProductURL:URLRequest = new URLRequest("/alternate/path/to/product/" + productID);
  var dataLoader:URLLoader = new URLLoader();

  dataLoader.load(altProductURL);
}

Answer 1

如果我错了，请纠正我，但 e.target 或 e.currentTarget 是失败的 URLLoader 吗？

Answer 2

您可以将错误处理程序包装在一个局部变量中（描述一个新函数），这样您就可以将 ID 传递给接收错误事件的方法：

function loadData(productID:String):URLLoader {
  var productURL:URLRequest = new URLRequest("/path/to/product/" + productID);
  var dataLoader:URLLoader = new URLLoader();

  var errHandler:Function = function(event:IOErrorEvent):void {
    handleDataError(event, productID);
  };

  dataLoader.addEventListener(Event.COMPLETE, parseData);
  dataLoader.addEventListener(IOErrorEvent.IO_ERROR, errHandler);
  dataLoader.load(productURL);

  return dataLoader;
}

function handleDataError(e:IOErrorEvent, productID:String) {
  var altProductURL:URLRequest = new URLRequest("/alternate/path/to/product/" + productID);
  var dataLoader:URLLoader = new URLLoader();

  dataLoader.load(altProductURL);
}

Answer 3

将错误处理程序包装在闭包中或从目标检索 id 的替代方法是编写一个隐藏重试机制的自定义加载器，因此您可以像使用普通加载器一样使用它。

类似这样的东西（我只是在记事本中写的，所以它可能有错误，但只是为了给你一个想法......）：

public class ProductDataLoader extends EventDispatcher {

    private var _paths:Array;
    private var _id:String;
    private var _state:int; 

    private var _loader:URLLoader;
    private var _data:Object;

    public function get data():Object {
        return _data;
    }

    public function ProductDataLoader(id:String) {
        _paths = [
            "/path/to/product/",
            "/alternate/path/to/product/"
        ];
        _id = id;
        _state = -1;

        _loader = new URLLoader();
        _loader.addEventListener(Event.COMPLETE, handleComplete);
        _loader.addEventListener(IOErrorEvent.IO_ERROR, handleError);   

    }

    public function load():void {
        if(hasNextPath()) {
            _loader.load(new URLRequest(getNextPath()));
        } else {
            //  here, we ran out of paths to try
            //  you shouldn't get here unless you call loadProduct() 
                    //      more than once. 
            //  you should probably throw an error here, but that's up to
        }

    }

    private function hasNextPath():Boolean {
        return _state < _paths.length - 1;
    }

    private function getNextPath():String {
        _state++;
        return _paths[_state] + _id;    
    }

    private function handleComplete(e:Event):void {
        // redispatch the complete event
        _data = _loader.data;
        dispatchEvent(e);
    }

    private function handleError(e:Event):void {
        if(hasNextPath()) {
            loadProduct();
        } else {
            //  we tried all paths without success
            //  so we just redispatch the error event
            dispatchEvent(e);
        }   
    }

}

然后在你的加载函数中：

function loadData(productID:String):URLLoader {

    var productLoader:ProductDataLoader = new ProductDataLoader(productId);
    dataLoader.addEventListener(Event.COMPLETE, parseData);
    dataLoader.addEventListener(IOErrorEvent.IO_ERROR, handleDataError);
    dataLoader.load();
}