将 ActionScript 对象强制转换为模型

Question

在 ActionScript 3 中是否有任何“自动方式”将“对象”转换为个性化模型数据类型？

例子：

package Example{
   public class ExampleModel{
       private _id:int;
       private _randomAttribute:String;

       public function ExampleModel(){
           _id = 0;
           _randomAttribute = "";
       }

       public function get id():int{
           return _id;
       }

       public function set id(value:int):void{
           _id = value;
       }

       public function get randomAttribute():String{
           return _randomAttribute;
       }

       public function set randomAttribute(value:String):void{
           _randomAttribute = value;
       }
   }
}

然后，在我的代码的某些部分，假设我有这样的东西：

var _obj:Object = new Object();
_obj.id = 1;
obj.randomAttribute = "Hello World";

我想要的是这样的：

var _exampleModel:ExampleModel = obj as ExampleModel;

但是当我这样做时，_exampleModel 上的结果为空。 有任何想法吗？ 谢谢。

编辑：

根据Manish的回答，我改变的只是p var的类型，它可以让我遍历每一种属性：

public function fromObject(obj:Object):void{
    //p:* includes every type of attributes.
    for (var p:* in obj)
        if (this.hasOwnProperty(p))
            // Set private var directly.
            this["_" + p] = obj[p];
}

感谢 Manish 和 rcdmk。 Manish 的回答对我来说已经足够了，根据 rcdmk 的评论，p:String 与循环将通过的数据类型无关，它实际上是属性的名称，它有意义，因为每个 name 都是 String。

Answer 1

自动“投射”它的唯一方法如下：

var model:Model = new Model();
var obj:Object = { id: "98123", name: "John Doe" };

for (var p:String in obj) {
    if (model.hasOwnProperty(p))
        model[p] = obj[p];
}

（注意：在我的示例中，Model.id 和 Model.name 都是 String 类型。）

当然，更合适的方法是将普通对象传递给Model对象，让Model对象吸收它。

var model:Model = new Model(obj);

或者：

var model:Model = new Model();
model.fromObject(obj);

您在Model 代码中的哪个位置：

public function Model(obj:Object = null)
{
    if (obj != null)
        fromObject(obj);
}

public function fromObject(obj:Object):void
{
    for (var p:String in obj)
        if (this.hasOwnProperty(p))
            // Set private var directly.
            this["_" + p] = obj[p];
}

此代码可以在您的抽象基类Model 中，并且您所有特定的Model 子类（例如ProductModel、CustomerModel 等）都可以自动使用它。

例如

public class ProductModel extends Model
{
    public function ProductModel(obj:Object = null)
    {
        super(obj);
    }
}