修改flash生成的xml？答案

【问题标题】：modify xml generated by flash?修改flash生成的xml？
【发布时间】：2011-07-09 08:27:29
【问题描述】：

我是 flash 和 actionscript 的新手。

flash的xml文件生成后我想修改一下。

你可以看这个教程 http://www.webwasp.co.uk/tutorials/A_IntAct-02-drag-drop/index.php 在这里，当我更改位置时，我想要更新的新 xml 文件。

非常感谢任何帮助。谢谢，

【问题讨论】：

页面上有很多示例，但没有一个引用 XML。你能扩展你想要完成的事情吗？
什么新的xml文件？有什么更新？
感谢您的回复。我正在研究拖放示例。如果我更改对象的 (x,y) 位置，那么它应该在 xml 文件中更新。我想知道如何在 xml 文件中更改它。

标签： actionscript-3 flash-builder flash

【解决方案1】：

几乎不知道您的要求是什么，我创建了一个可以拖放的正方形示例。当它被丢弃时，它将 xml 写入一个带有被丢弃正方形的 x 和 y 坐标的 xml 文件：

package 
{
    import flash.display.*;
    import flash.events.*;
    import flash.filesystem.*;
    import flash.utils.*;

    public class Main extends Sprite 
    {
        private var _square:Square;

        public function Main():void 
        {
            _square = new Square();
            _square.addEventListener(MouseEvent.MOUSE_DOWN, onSquareMouseDown);
            addChild(_square);

        }// end function

        private function onSquareMouseDown(e:Event):void
        {
            _square.startDrag();

            stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);

        }// end function

        private function onStageMouseUp(e:Event):void
        {
            stage.removeEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
            _square.stopDrag();

            var xml:XML = <dragAndDrop>
                              <x>{_square.x}</x>
                              <y>{_square.y}</y>
                          </dragAndDrop>;

            var file:File = File.desktopDirectory.resolvePath("xml/dragAndDrop.xml");
            var fileStream:FileStream = new FileStream();
            fileStream.open(file, FileMode.WRITE);
            fileStream.writeMultiByte(String(xml), "iso-8859-01");
            fileStream.close();

        }// end function

    }// end class

}// end package

import flash.display.Sprite;

internal class Square extends Sprite
{
    public function Square()
    {
        graphics.beginFill(0xFF0000);
        graphics.drawRect(0, 0, 100, 100);
        graphics.endFill();

    }// end function

}// end class

【讨论】：

@Hardik Patel，仅供参考，这是一个纯 AS3 的 Air 项目。 FileStream 仅适用于 Air。

【解决方案2】：

网站上给出的例子是指mx 2004。你可以看到一个更新的example here。

【讨论】：