找到按钮但无法点击

Question

我尝试运行的 SDK 首先有一个准备安装步骤，然后显示下一步按钮。所以我一直等到看到按钮。

当下一个按钮出现时，ConsolWrite 在循环中写入。但我无法点击按钮。也试过 send("!n") 还是不行。

 #include <GUIConstantsEx.au3>

Global $hCtrl = 0, $Waiting = True

$wintitle = "SigCaptureWeb SDK - InstallShield Wizard"
ShellExecute("C:\SigCaptureWeb.exe")

; your GUI loop
While (1)
    If $Waiting And WinExists($wintitle) Then
        $hCtrl = ControlGetHandle($wintitle, "", "[CLASS:Button; TEXT:&Next >]")
        If $hCtrl Then
            ; we got the handle, so the button is there
            ; now do whatever you need to do
            ConsoleWrite("in the loop")
            ControlClick($wintitle,"", "[CLASS:Button; TEXT:&Next >]","{ENTER}")
            $Waiting = False
        EndIf
    EndIf

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Answer 1

您可能需要以管理员身份运行脚本才能与以管理员身份运行的安装程序进行交互。

使用ShellExecute 测试 AutoIt 安装程序允许脚本检测窗口，尽管单击按钮不起作用，因为脚本以非管理员身份运行。这可以被认为是操作系统的一项安全功能，以保护管理进程。

这可能对你有用。我不确定你为什么有 gui 代码等，所以我把它排除在外。

; This is a compile directive to make the compiled script run as admin.
#pragma compile(ExecLevel, requireAdministrator)

; This directive is for uncompiled script to run as admin.
#RequireAdmin

$wintitle = "SigCaptureWeb SDK - InstallShield Wizard"
Run("C:\SigCaptureWeb.exe")

WinWait($wintitle)

; Wait for Next button to become visible.
While Not ControlCommand($wintitle, "", "&Next >", "IsVisible", "")
    Sleep(250)
WEnd

ControlClick($wintitle, "", "&Next >")

作为 InstallShield 安装程序，它可能具有参数，您可以将这些参数传递给可执行文件以启动静默安装，这可能会使其更容易。你可以调查一下。