将 replaceAll 方法添加到 ActionScript String 类

Question

在将替换所有功能添加到我的 Flex 项目中时，我需要一些帮助。我希望以尽可能自然的方式来做这件事。

我想要实现的是能够运行这段代码（使用 Flex 编译器）"aabbaaba".replaceAll("b","c") 并获得 "aaccaaca"。我还想链接replaceAll 调用。
注意：我实际上不会用cs 替换bs，而是在编码时不知道的各种字符串！

我不想要的：
1. 使用带有全局标志的正则表达式。要替换的标记是确定的广告运行时间，将它们转换为正则表达式并不简单。
2. 使用StringUtil.replace 方法。这是一个静态方法，链接很丑。
3.链split和join。因为在阅读代码时可能会让其他人感到困惑。
4.禁用严格类型检查。我想对我的其余代码进行类型检查。

---

这是我目前所拥有的：

String.prototype.replaceAll = function(replace:String, replaceWith:String):String{
    return this.split(replace).join(replaceWith);
}

并且可以这样调用：

"aababacaaccb"["replaceAll"]("b", "c")["replaceAll"]("c", "a");

---

另外，是否有反对通过原型扩展对象的建议？ 我也会接受一个强烈反对通过原型扩展 String 对象的答案。

谢谢你，
阿林

Answer 1

第二个答案是这样的：

为String编写包装类StringEx，你可以定义replaceAll像这样被链接

public function replaceAll(replace:String, replaceWith:String):StringEx {
   string = string.replace(new RegExp(replace, 'g'), replaceWith);
   return this;
}

通过提供 toString()，您可以轻松地将 StringEx 对象更改为 String

var result:String = "" + new StringEx("aaccaaca").replaceAll('b', 'c').replaceAll('c', 'a');

你可以在这里获得完整版：OOP way of prototype extension - wonderfl build flash online

Answer 2

我认为您已经获得了所有可能的技术答案。我将详细说明我认为处理这种语言的最佳方式。

不推荐在诸如 AS3 之类的 OOP 语言中使用原型（主要是因为它们不符合封装性）。您暗示您不想要“让他人感到困惑”的东西（与 split.join 相关）；好吧，AS3 中的原型非常混乱。 举个例子，原型声明可以在代码中的任何地方完成，因此它应该驻留在哪里并不明显。如果“其他人”在您的代码中遇到“foo”.replaceAll()，那么在哪里可以找到该方法并检查它的实际作用并不明显。

静态函数修正了这一点并且非常简单。当然，你需要一个额外的参数，而且你不能真正正确地链接，但这是一件坏事吗？

如果您需要性能，split.join 是不二之选。我敢打赌，比起原型的使用，更多的 AS3 开发者知道 split.join。

另一方面，我认为最语义化和最实用的方法是使用自己的语言方法（因此我之前的回答）。您正在尝试用 AS3 中的另一个字符串替换字符串中的所有针，为此，该语言具有带全局标志的 String::replace 方法。我很确定有一种方法可以轻松解析和使用正则表达式中的任何字符串。

我同意在某些情况下可能需要辅助方法（如 replaceAll），但我强烈建议您不要使用原型，而是使用更标准的方法，如 StringUtil.replace。

Answer 3

我不想要的： 1. 使用带全局标志的正则表达式

为什么不呢？对于简单的字符串替换非常简单且高效：

"aababacaaccb".replace(/b/g, "c");

或者如果您愿意：

var needle:String="b";
"aababacaaccb".replace(new RegExp(needle,"g"), "c");

我不建议为此使用原型，它不是非常 OOP 也不是标准......对于这样一个简单的操作来说感觉太hacky了。

Answer 4

我想不出满足您发布的 4 个要求的方法。但我认为，如果您的主要目标是一次性替换各种标记（您希望通过链接调用实现的目标）同时能够使用任何字符串作为标记，您可以尝试这样的事情：

public class StringUtil {
    public static function replaceAll(source:String,map:Object):String {
        for(var replaceToken:String in map) {
            source = source.split(replaceToken).join(map[replaceToken]);
        }
        return source;
    }
}

var str:String = "a1ccca111a";

str = StringUtil.replaceAll(str,{
    'a' : 'b',
    '1' : '2'
});
trace(str);

请记住一个警告。对于 Object 对象，不能保证顺序。在大多数情况下，这并不重要，但如果在您的情况下，您可以改用数组，并在每个插槽中存储令牌及其替换（例如作为对象）。

Answer 5

"aabbaaba".split('b').join('c') 返回“aaccaaca”

UPD：
我想知道为什么它对你来说是不可接受的（但是它不支持正则表达式）：它工作得非常快（在严重的循环中检查它）并且完全符合你的要求。

还有一些您的黑名单中没有提到的解决方案（顺便说一句，静态函数比弄乱原型更好 - 恕我直言）：

• 您可以仅使用replaceAll 方法和super() 调用来扩展String 类。如果您检查(myStringInstance is String)，此类的实例将返回true
• 和另一个解决方案：创建一个包装器而不是扩展：一个将为您存储一个字符串的类提供额外的功能（虽然我无法想象一个字符串），并且可能将它的一些属性设置为只读。或者它可能只有一个 getter 和 setter

Answer 6

我有两个答案给你。第一个是你想要的。但我推荐第二个。

在 flex 中启用原型非常简单，可以通过设置 flex-config 来完成

ReplaceAllTest.as

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    public class ReplaceAllTest extends Sprite
    {
        public function ReplaceAllTest() 
        {
            var tf:TextField = new TextField;
            String.prototype.replaceAll = function(replace:String, replaceWith:String):String{
                return this.split(replace).join(replaceWith);
            }
            // now the strict mode is off compiler does NOT warn the following code
            tf.text = "aababacaaccb".replaceAll("b", "c")
                                    .replaceAll("c", "a");
            addChild(tf);
        }
    }
}

ReplaceAllTest-config.xml

<?xml version="1.0" encoding="utf-8" ?>
<flex-config>
    <compiler>
       <as3>false</as3>
       <es>true</es>
       <strict>false</strict>
    </compiler>
    <static-link-runtime-shared-libraries>true</static-link-runtime-shared-libraries>
</flex-config>

我仍然不鼓励这种方式，因为启用原型设计和关闭严格模式会减慢您的代码速度。

Answer 7

我知道这是一个旧线程，但这是我想出的可以做任何常规字符串的方法。

    public static function replaceAll(p_string:String, p_search:String, p_replaceWith:String):String{

    //Dummy Control
        if(p_string == null)
            return '';

    //Iterates through the string from right to left so we don't go over what we are changing.
        var index:int = p_string.lastIndexOf(p_search);
        while(index != -1){

        //Splits the string at the index
            p_string = p_string.slice(0, index) + p_replaceWith + p_string.slice(index+p_search.length);

        //Attempts to find the next index
            index = p_string.lastIndexOf(p_search, index-1);//We -1 so we always move down the line
        }

    //Returns the modified p_string
        return p_string;
    }