AS3 - 你如何忽略一个类（错误 #1009）？

Question

我为 MovieClip 创建了一个类，为玩家 (char) 创建硬币以供拾取。假设该课程所做的只是添加分数和硬币收集变量，然后从舞台上移除一枚硬币。但是当我使用gotoAndStop(#); 更改框架时，控制台垃圾邮件

ErrorType：错误 #1009：无法访问空对象引用的属性或方法。"

硬币类：

public class coin extends MovieClip{
    var char:MovieClip;
    var MainTimeLine = MovieClip(root);
    public function coin() {
        // constructor code
            this.addEventListener(Event.ENTER_FRAME,update);

    }

    function update(event:Event):void{
        if(MainTimeLine.currentFrame!=5){
            char=MovieClip(root).char;
            if(this.hitTestObject(char)){
                this.removeEventListener(Event.ENTER_FRAME,update);
                parent.removeChild(this);
                MainTimeLine.score++;
                MainTimeLine.coinscollected++;
            }
        }
    }

}

Answer 1

在您的显示对象被添加到显示列表之前，不会填充根目录。您需要在设置变量之前监听该事件。

var char:MovieClip;
var MainTimeLine; //do not initialize here, root is null at this point

public function coin() {
    // constructor code

    //root is still null here sometimes too, so see if it's populated yet
    if(root){
        init(); //root is populated, skip to initialization
    }else{
        this.addEventListener(Event.ADDED_TO_STAGE,addedToStage);  //root isn't populated yet, listen for added to stage and then initialize
    }
}

private function addedToStage(e:Event = null):void {
    this.removeEventListener(Event.ADDED_TO_STAGE,addedToStage);
    init();
}

private function init():void {
    MainTimeLine = MovieClip(root)
    this.addEventListener(Event.ENTER_FRAME,update);
}

---