如何在 Flash 中获取格式化文本？

Question

用setTextFormat 来格式化文本很简单。但是是否有任何有效的方法来检索对文本所做的所有样式？ getTextFormat 是已知的，但它不适用于格式不同的文本。有什么想法吗？

Answer 1

至少可以这么说，这是很多工作。

我推荐一个现有的富文本编辑器，您可以将其插入到您的解决方案中，例如 obedit : http://www.oblius.com/projects/obedit/ (donationware)

编辑：

好的，作为对您的评论的回应，您通过实现样式文本标准（例如 text/enriched MIME 内容类型 (https://www.rfc-editor.org/rfc/rfc1896) 或更可能的 Rich Text Format (http://msdn.microsoft.com/en-us/library/aa140277(office.10).aspx) 来编写富文本编辑器）。您也可以使用 HTML 或创建自己的语法。

假设用户键入The quick brown fox jumps over the lazy dog. 用户突出显示“快速”并单击粗体按钮（您提供），突出显示狐狸并将前景更改为红色（使用您提供的颜色选择器）。从视图中隐藏，您将数据字段的值更改为 The \bquick\b brown \{color:red}fox\{\color} jumps over the lazy dog.

现在用户突出显示整行并将其设置为绿色。您将隐藏值更改为 \{color:green}The \bquick\b brown fox jumps over the lazy dog.\{color} 请注意，您必须解析该行以识别和删除冲突的颜色标记。如果用户想要撤消该更改怎么办？你用红狐保存过版本吗？当用户在行尾输入新文本时，你认为插入符号在绿色标签之内还是之外？

当您重新加载该值时，您必须再次解析该行，然后将所有格式转换为 Flash 可以显示的内容，从而去除标签。

重新发明轮子并不好玩。

Answer 2

正如你所说，getTextFormat(beginIndex:int = -1, endIndex:int = -1) 只返回一个 TextFormat 对象，其中填充了指定文本范围的格式信息（只有指定的整个文本共有的属性才会在结果 TextFormat 对象中设置）。

如果要全文的格式信息，请在调用setTextFormat后读取TextField的htmlText属性。它包含文本字段内容的 HTML 表示。

var str:String = "The quick brown fox jumps over the lazy dog\n";
var tf:TextField = new TextField();
tf.multiline = true;
tf.text = str + str + str;
var f:TextFormat = new TextFormat("Arial", 15, 0xFF0000, true, false, 
    true, null, null, TextFormatAlign.CENTER);
tf.setTextFormat(f, 0, str.length);
f = new TextFormat("Courier New", 12, 0x00FF00, false, false, 
    false, "http://www.google.com", null, TextFormatAlign.LEFT);
tf.setTextFormat(f, str.length, 2 * str.length);
f = new TextFormat("Times New Roman", 12, 0x0000FF, false, true, 
    true, null, null, TextFormatAlign.RIGHT);
tf.setTextFormat(f, 2 * str.length, str.length * 3);
tf.width = 400;
tf.height = 300
addChild(tf);
trace(tf.htmlText);

输出是：

<P ALIGN="CENTER">
    <FONT FACE="Arial" SIZE="15" COLOR="#FF0000" LETTERSPACING="0" KERNING="0">
        <B>
            <U>The quick brown fox jumps over the lazy dog</U>
        </B>
    </FONT>
</P>
<P ALIGN="LEFT">
    <FONT FACE="Courier New" SIZE="12" COLOR="#00FF00" LETTERSPACING="0" KERNING="0">
        <A HREF="http://www.google.com" TARGET="">The quick brown fox jumps over the lazy dog</A>
    </FONT>
</P>
<P ALIGN="RIGHT">
    <FONT FACE="Times New Roman" SIZE="12" COLOR="#0000FF" LETTERSPACING="0" KERNING="0">
        <I>
            <U>The quick brown fox jumps over the lazy dog</U>
        </I>
    </FONT>
</P>