根据给定的字符串列表创建编号列表

Question

windows cmd 批处理

我有一个如下所示的文本文件：

Dog
Cat
Frog
Bat
Bird
Mouse

我想为每个字符串、每一行分配一个数字。

这样就变成了

1 Dog
2 Cat
3 Frog
4 Bat
5 Bird
6 Mouse

然后我想要求用户输入一个数字，然后将对应的字符串存储在变量中。

所以如果用户输入 1，那么变量设置为字符串 Dog
因此，当用户输入 1 时，程序存储/输出 Dog

set /p var1="number? " 所以 var1 变成了字符串，而不是数字。

这有点像任务的第一部分，但现在我需要第二部分，将字符串存储在变量中。

@echo off
set TEXT_T="list.txt"

set /a c=0

setlocal ENABLEDELAYEDEXPANSION

FOR /F "tokens=1 usebackq" %%i in (%TEXT_T%) do (
  set /a c=c+1

  echo !c! %%i 
)
endlocal
pause

感谢 LotPings，以下是更新后的答案。

稍作调整即可通过字符串请求文件夹

这提供了一种从 CMD 使用 Megatools 的更简单方法

https://megatools.megous.com/man/megals.html
https://github.com/megous/megatools

@echo off

:start:

megals /Root/

set /p var1="dir? " & megals /Root/%%var1%%

for /f "tokens=1,* delims=:" %%A in ('megals -n /Root/%%var1%% ^|findstr
/n "." ') do (
set Link[%%A]=%%B
Echo %%A %%B
)

for /f "tokens=1,* delims=:" %%A in ('megals -n -e /Root/%%var1%% ^|findstr
/n "." ') do (
set Link[%%A]=%%B
)

set /p choice=Select #:
Call Set Link=%%Link[%choice%]%%

set "trimmedlink="
for %%h in (%Link%) do if not defined trimmedlink set "trimmedlink=%%h"
Megadl %trimmedlink% && goto :start:

pause

编辑：必须将%Link% 修剪为第一个单词，即链接

Megals -e /Root/misc 的输出如下所示： 星号是文件的唯一链接 ID

                                                    /Root/misc
   https://mega.nz/#!********!********************* /Root/misc/File1
   https://mega.nz/#!********!********************* /Root/misc/File2
   https://mega.nz/#!********!********************* /Root/misc/File3

上面的批处理脚本看起来像：

1 File1
2 File2
3 File3
Select #:  <------input file number 

Edit2号码列表已修复

Edit3 文件名中的括号会使程序崩溃 即

1 File(1)

然后将选择的文件号作为相应链接传递给Magadl
Megadl Link

批处理脚本允许您只需输入相应的文件号即可下载链接，因此您无需在标准 cmd 窗口中输入长链接 ID。

Answer 1

直接使用 megals 输出并避免延迟扩展（删除 !）
Findstr /n 将进行编号。

@echo off
for /f "tokens=1,* delims=:" %%A in ('megals -e /Root/ ^|findstr /n "." ') do (
  set Item[%%A]=%%B
  Echo %%A %%B
)
set /p choice=Select #:
Call Echo Choice:%%Item[%choice%]%%

使用带有双百分号的（伪）调用是一种老式的实现延迟扩展的方法，而不会出现! 的问题。

在编程/脚本编写中，您需要调整技术以满足您的需求。

在不知道您的巨型工具的确切输出的情况下，
这可以完成这项工作：

@echo off
for /f "tokens=1,* delims=:" %%A in ('megals -e /Root/ ^|findstr /n "." ') do (
  set Folder[%%A]=%%B
  Echo %%A %%B
)
set /p choice=Select #:
Call Set Folder=%%Folder[%choice%]%%

for /f "tokens=1,* delims=:" %%A in ('megals -e %Folder% ^|findstr /n "." ') do (
  set Link[%%A]=%%B
  Echo %%A %%B
)
set /p choice=Select #:
Call Set Link=%%Link[%choice%]%%

megadl %Link%

根据 compo 的建议，请edit您的问题包含所有必要信息 - 不要强迫他人从不必要的答案和 cmets 中收集。

Answer 2

只使用一个数组：

@echo off
setlocal ENABLEDELAYEDEXPANSION

set TEXT_T="list.txt"

set /a c=0

FOR /F "tokens=1 usebackq" %%i in (%TEXT_T%) do (
  set /a c=c+1
  echo !c! %%i 
  set string[!c!]=%%i
)

set /P number=Enter number:
echo !string[%number%]!

pause

更多详情，请参阅this answer。

Answer 3

将命令的输出变成列表而不是文本文件变成列表怎么样？

因此，此处带有 var1 的行将转换为编号列表（该目录中列出的文件），而 Var2 是用户输入的数字，以创建传递给命令的返回字符串。即
https://megatools.megous.com/man/megals.html

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
(megals -e /Root/) <--------list all folders in root
(set /p var1="dir? " && megals -e /Root/!var1!) <-- select folder + list files
(set /p var2="Megalink? " && Megadl !var2!) <--- enter the file name for download
ENDLOCAL
pause

我希望能够为下载输入一个数字，而不是长文件名。因此，用户可以输入与他们要下载的链接对应的数字。因此，如果他们输入 1，那么程序会执行 Megadl Dog

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

megals -e /Root/

set /p var1="dir? "

megals -e /Root/!var1! > rlist.txt

set TEXT_T="rlist.txt"

set /a c=0

FOR /F "tokens=1 usebackq" %%i in (%TEXT_T%) do (
set /a c=c+1
echo !c! %%i 
set string[!c!]=%%i
)

set /P number=Enter number:
Megadl !string[%number%]!
Endlocal
pause

这会杀死链接的第一部分，因为它会删除中间的所有内容，包括感叹号。 !dasasdasd!
所有超链接都以 #!something! 开头！

Answer 4

这没用

我需要将 Call Echo %%Item[%choice%]%% 的输出传递给 Megadl

@echo off
for /f "tokens=1,* delims=:" %%A in ('megals -e /Root/anime ^|findstr /n "." ') do (
set Item[%%A]=%%B
Echo %%A %%B
)
set /p choice=Select #:
Call Echo %%Item[%choice%]%%

for /F "tokens=*" (`%%Item[%choice%]%%`) do (
set "var1=%%A"
Megadl !Var1!
)
pause