防止无意的批处理文件运行

Question

为了防止无意的run of batch files 在某些文件夹中产生不良行为，我将这 3 行添加到所有批处理文件的开头。

@echo off
set /p choice=Are you sure to run this file, if so press 'y' anything else cancels? 
if /I %choice% neq y notepad %~f0
.
. rest of the code
.

因此，如果用户按下y，文件将执行预期操作，否则notepad 将打开它进行编辑，例如单击.ps1 文件，但控制台窗口保持打开状态，直到我关闭记事本或关闭控制台，读取this post 表明我所做的并不理想。

记事本打开文件后有没有办法关闭控制台。

Answer 1

最简单的方法是使用内置的choice.exe 实用程序、Start 命令，当然还有Exit 命令。 (windows-vista+)

@%SystemRoot%\System32\choice.exe /M "Are you sure to run this file"
@If ErrorLevel 2 Start %SystemRoot%\System32\notepad.exe "%~f0" & Exit
@Echo Off
.
. rest of the code
.

[编辑/]

这是一种替代方法，正如我在下面的评论中提到的那样。

@%SystemRoot%\System32\choice.exe /C YN /N /D N /T 5 /M "Are you sure to run this file"
@If ErrorLevel 2 Start %SystemRoot%\System32\notepad.exe "%~f0" & Exit
@Echo Off
.
. rest of the code
.

我建议您使用choice.exe 的原因是Set /P 命令具有潜在危险。有了它，最终用户可以随意输入任何内容，包括故意的恶意字符或命令。因此，您的代码需要在不运行它的情况下稳健地解析该输入，以免破坏您的脚本，或更糟。

这是使用Set /P 执行类似功能的方法示例。

@Set "#="& Set /P "=Are you sure to run this file? If so, press 'y', anything else cancels"<Nul
@For /F Skip^=1^ Delims^=^ EOL^= %%# In ('%SystemRoot%\System32\replace.exe ? . /U /W') Do @If Not Defined # Set "#=%%#"
@(Set #) 2> NUL | %SystemRoot%\System32\findstr.exe /ILX "#=Y" 1> NUL || (
    Start %SystemRoot%\System32\notepad.exe "%~f0"& Exit)
@Echo Off
.
. rest of the code
.