【问题标题】:Need a batch file or a shell file that will take the current calendar month, and make directories for each day.需要一个批处理文件或一个 shell 文件,该文件将占用当前日历月,并为每一天创建目录。
【发布时间】:2014-09-03 00:45:22
【问题描述】:

这是我第一次在这里发帖,如果我做错了什么,我深表歉意。 我需要一个可以在月初运行的批处理文件或 shell 文件,以便为该月的每一天创建具有以下格式 YYYYMMDD 的文件夹名称的目录。所以本质上我会有一个名为(让我们在这里举个例子,只说报告。 在报告文件夹中,我需要整个日历月的文件夹 20140901 20140902。

到目前为止,我有这个代码:

echo var D = new Date() > tmp.js 
echo D = (D.getFullYear()*100+D.getMonth()+1)*100+D.getDate() >> tmp.js 
echo WScript.Echo( 'set YYYYMMDD='+D ) >> tmp.js 
echo @echo off > tmp.bat 
cscript //nologo tmp.js >> tmp.bat 
call tmp.bat
mkdir %YYYYMMDD%

我知道您也可以根据本地日期创建一个文件夹,但是我不确定告诉它“跳到 2014 年 10 月 1 日之前所需的逻辑。 任何帮助将不胜感激。

【问题讨论】:

    标签: windows shell batch-file


    【解决方案1】:
    @ECHO Off
    SETLOCAL ENABLEDELAYEDEXPANSION
    FOR /f "tokens=1-3delims=./- " %%a IN ("%date%") DO (
     CALL :SETsz yy %%c
     CALL :SETsz mm %%b
    )
    IF %yy% lss 2000 SET /a yy+=2000
    SET cdate=31
    FOR %%a IN (2 2 2 4 6 9 11) DO IF %%a==%mm% SET /a cdate-=1
    SET /a cdate=((%yy%*100)+%mm%)*100+%cdate%
    SET /a yy=%yy% %% 4
    IF %yy%%mm%==02 SET /a cdate+=1
    FOR /L %%a IN (1%cdate:~-2%,-1,101) DO ECHO(MD reports\!cdate!&SET /a cdate-=1
    
    GOTO :EOF
    :setsz
    SET cdate=%2
    IF %cdate:~0,1%==0 (SET %1=%cdate:~1%) ELSE (SET %1=%2)
    GOTO :eof
    

    所需的 MD 命令仅用于测试目的ECHOed。 验证命令正确后,将ECHO(MD 更改为MD 以实际创建目录。附加 2>nul 以抑制错误消息(例如,当目录已存在时)

    这变得更加复杂,因为您没有告诉我们您使用哪种特定的日期格式。它应该适用于任何分隔符,但我使用我的格式 dd/mm/yyyy 进行测试。如果您使用抑制前导零或两位数的年份,它应该按原样工作。

    如果您使用前导日期名称,则需要将 tokens 更改为 2-4 以代替 1-3。第一个for“循环”中使用的特定字段%%b 和%%c 需要为%%a、%%b 或%%c,具体取决于您在日期格式中使用的顺序。

    您可以通过使用来测试例程

    set date=1/02/2012
    

    (例如)在“FOR /f ...”行之前的行中。通常,我会警告不要尝试更改date,因为它是系统建立的“魔法变量”,覆盖它会导致混乱。然而,在这种情况下,它遵循setlocal 命令,因此插入的日期覆盖将在例程结束时退出;因此在测试期间是安全的。

    【讨论】:

    • 这似乎完全像我需要的那样工作,但是我确实注意到了一次问题。当我运行您的脚本时,它将年份字段设置为 2002 而不是 2014。我们在这里使用 9/2/2014 格式。对不起,我忘了包括那个。这是我需要添加的东西吗?这是我为使代码正确所做的工作,但是我认为这不是正确的解决方法。 IF %yy% lss 2000 SET /a yy+=2012
    • 我建议您的日期格式实际上是 Wed(nesday) 9/2/2014,意思是 2014 年 9 月 2 日。您需要将 tokens 更改为 2-4 而不是 1-3,就像我提到的那样,您需要:setsz mm %%a 代替:setsz mm %%b。
    【解决方案2】:

    此代码的前四行将在 XP Pro 及更高版本中为您提供可靠的 YY DD MM YYYY HH Min Sec 变量。

    for 循环在运行时只会为该年份和月份创建 31 个文件夹。

    @echo off
    for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
    set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
    set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
    
    for /L %%a in (1,1,31) do if %%a LSS 10 (md %YYYY%%MM%0%%a) else (md %YYYY%%MM%%%a)
    pause
    

    【讨论】:

      【解决方案3】:

      Magoo 你的回答奏效了。我真的很感激。

      这是我最终使用的。

      @ECHO Off
      SETLOCAL ENABLEDELAYEDEXPANSION 
      FOR /f "tokens=2-4delims=./- " %%a IN ("%date%") DO (
       CALL :SETsz yy %%c
       CALL :setsz mm %%a
      )
      IF %yy% lss 2000 SET /a yy+=2000
      SET cdate=31
      FOR %%a IN (2 2 2 4 6 9 11) DO IF %%a==%mm% SET /a cdate-=1
      SET /a cdate=((%yy%*100)+%mm%)*100+%cdate%
      SET /a yy=%yy% %% 4
      IF %yy%%mm%==02 SET /a cdate+=1
      FOR /L %%a IN (1%cdate:~-2%,-1,101) DO MD C:\Users\spoling\Desktop\!cdate!&SET /a cdate-=1
      
      GOTO :EOF
      :setsz
      SET cdate=%2
      IF %cdate:~0,1%==0 (SET %1=%cdate:~1%) ELSE (SET %1=%2)
      GOTO :eof
      

      【讨论】:

        猜你喜欢
        • 1970-01-01
        • 1970-01-01
        • 2010-09-10
        • 2023-03-22
        • 1970-01-01
        • 2013-08-28
        • 1970-01-01
        • 2013-04-21
        • 1970-01-01
        相关资源
        最近更新 更多