无法使用“FOR”命令设置变量

Question

我正在尝试从“for /f”命令设置几个变量，并且在我回显它们时总是得到“ECHO 已关闭”：

ipst.txt 文件：

1     10.1.1.10
3     10.1.3.10
8     10.1.3.10

批处理文件：

@ECHO OFF
set Computerslist=ipst.txt

for /f "tokens=1,2" %%A in (%Computerslist%) do (
    set StationNumber=%%A
    set StationIP=%%B
    echo %StationNumber%
    echo %StationIP%
    )

结果是：

ECHO is off.
ECHO is off.

这个问题使我无法获取变量并将它们与更多循环一起使用。 需要你的帮助:)

Answer 1

MC ND 是正确的。选择以下 2 种方式之一：

@ECHO OFF
set Computerslist=ipst.txt

for /f "tokens=1,2" %%A in (%Computerslist%) do (
    set "StationNumber=%%A" & echo.%%A
    set "StationIP=%%B" & echo.%%B
    )

或

@ECHO OFF
setlocal enabledelayedexpansion
set Computerslist=ipst.txt

for /f "tokens=1,2" %%A in (%Computerslist%) do (
    set StationNumber=%%A
    set StationIP=%%B
    echo.!StationNumber!
    echo.!StationIP!
    )

Answer 2

@ECHO OFF
    setlocal enableextensions enabledelayedexpansion

    set "Computerslist=ipst.txt"

    for /f "tokens=1,2 usebackq" %%A in ("%Computerslist%") do (
        set "StationNumber=%%A"
        set "StationIP=%%B"
        echo !StationNumber!
        echo !StationIP!
    )

但是，正如 cmets 中所指出的，仅当在更改变量的块内访问更改的变量时才需要延迟扩展。所以，这段代码

@ECHO OFF
    set "Computerslist=ipst.txt"

    for /f "tokens=1,2 usebackq" %%A in ("%Computerslist%") do (
        set "StationNumber=%%A"
        set "StationIP=%%B"
    )
    echo %StationNumber%
    echo %StationIP%

在这里，对变量值的访问不是在它发生变化的同一块中完成的，因此不需要延迟扩展。

已编辑 - 如 cmets 中所述，最后一段代码并未列出文件中的所有行。当 for 循环遍历它们时，先前的值将被覆盖，并且变量仅保存最后分配的值，该值将回显到控制台。我的错，选择了错误的样本。