如何检查参数（或变量）是否是批处理脚本中的数字

Question

我需要检查传递给 Windows 批处理文件的参数是否为数值。检查也适用于变量会很好。

我发现answer 与类似的question 相似，其中findstr 命令与正则表达式一起使用。

我确实尝试了该解决方案，但它并没有像我希望的那样工作（至少在 Windows 7 上）。

我的测试场景如下：

AA  # not a valid number
A1  # not a valid number
1A  # not a valid number

11  # a valid number

Answer 1

SET "var="&for /f "delims=0123456789" %%i in ("%1") do set var=%%i
if defined var (echo %1 NOT numeric) else (echo %1 numeric)

酌情将%1替换为%yourvarname%

Answer 2

对于± integers（也测试前导零）：

echo(%~1|findstr "^[-][1-9][0-9]*$ ^[1-9][0-9]*$ ^0$">nul&&echo numeric||echo not numeric

Answer 3

你可以试试这个。传递的变量例如是var 和%var% 等于500。

set /a varCheck=%var%
if %varCheck% == %var% (goto :confirmed) else (exit /B)
exit /B

:confirmed
:: You can use %var% here, and it should only be executed if it is numerical!

如果%var% 等于例如a3453d，则将varCheck设置为0，由于0不等于a3453d，则退出批处理。

（第 3 行的退出是为了以防 if 语句由于某种原因决定不执行……XD。）

Answer 4

最简单的正整数应该是：

IF 1%1 NEQ +1%1 echo Notnumeric!

如果还要考虑负数（连字符），这将起作用

SET number=%1
if 1%1 EQU +1%1 echo positive number
if %1==-%number:-=% echo negative number

向this article here学习

Answer 5

@hornzach - 你是如此亲密，而且答案比其他人简单得多。

隐藏错误消息（至少是win 7）重定向到标准错误输出（2）到nul（一个特殊的文件，它悄悄地丢弃输出“bit-bucket”）

set /a varCheck = %var% 2>nul

那么您的其余答案适用于 4 个测试用例。

完整的测试用例答案：

call :CheckNumeric AA  "#NOT A VALID NUMBER"
call :CheckNumeric A1  "#NOT A VALID NUMBER"
call :CheckNumeric 1A  "#NOT A VALID NUMBER"

call :CheckNumeric 11  "#A VALID NUMBER"

call :CheckNumeric 1.23456789012345678901234567890.123456  "#NOT A VALID NUMBER"
goto :EOF

:CheckNumeric
@ECHO.

@ECHO Test %1
set /a num=%1 2>nul

if {%num%}=={%1} (
    @ECHO %1 #A VALID NUMBER, Expected %2
    goto :EOF
)

:INVALID
    @ECHO %1 #NOT A VALID NUMBER, Expected %2

输出：

Test AA
AA #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test A1
A1 #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test 1A
1A #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test 11
11 #A VALID NUMBER, Expected "#A VALID NUMBER"

Test 1.23456789012345678901234567890.123456
1.23456789012345678901234567890.123456 #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Answer 6

做和上面一样的事情。特殊字符有问题。但是，解决方案是不同的方法。

@echo off
cls
setlocal enabledelayedexpansion

if "%1"=="" (goto:eof) else (set _VAR2CHECK=%1)

for /l %%a in (0,1,9) do (
   if defined _VAR2CHECK (set "_VAR2CHECK=!_VAR2CHECK:%%a=!") else (goto :end)
)

:end
if defined _VAR2CHECK (echo %1 #NOT A VALID NUMBER) else (echo %1 #A VALID NUMBER)

set "_VAR2CHECK="
endlocal

测试场景：

C:\>ISNUM 1A
1A  #NOT A VALID NUMBER

C:\>ISNUM 11
11  #A VALID NUMBER

Answer 7

只需尝试除以 1。 但它不适用于 Z 以外的数字（非相对整数或小数）。

set var=29
set /a number=%var% >nul 2>&1
set /a number=%number% / 1 >nul 2>&1
if "%var%" == "%number%" (echo numeric) else (echo NOT numeric)

Answer 8

我改用这个函数，它似乎对我有用，没有任何问题...

脚本 (mytestscript.bat)

REM == Script variables =============================================
SET "NUMCODE=%1"
SET "NAME=%2"

REM == Main script ==================================================
CALL :Validate "NUMCODE"
IF ERRORLEVEL 1 EXIT /B %ERRORLEVEL%
CALL :Validate "NAME"
IF ERRORLEVEL 1 EXIT /B %ERRORLEVEL%

ECHO Validation Complete and all variables passed validation.

REM == Functions ====================================================
:IsNumeric [string-value] [return-val]
    SET "stringVal=%~1"
    SET /A numericVal=%stringVal% > nul 2> nul
    IF "%stringVal%"=="%numericVal%" (SET "%~2=1") ELSE (SET "%~2=0")
    EXIT /B 0

:Validate
    SET PASSEDVALIDATION=0

    ECHO Validating %~1...

    IF "%~1"=="NUMCODE" (
        ECHO - Value: %NUMCODE%
        IF NOT "%NUMCODE%"=="" SET PASSEDVALIDATION=1
        IF "!PASSEDVALIDATION!"=="1" (
            CALL :IsNumeric %NUMCODE% RETVAL
            SET PASSEDVALIDATION=!RETVAL!
        )
        IF "!PASSEDVALIDATION!"=="1" (
            IF NOT %NUMCODE% GEQ 1 SET PASSEDVALIDATION=0
        )
        IF "!PASSEDVALIDATION!"=="1" (
            IF NOT %NUMCODE% LEQ 526 SET PASSEDVALIDATION=0
        )
        IF "!PASSEDVALIDATION!"=="0" (
            ECHO - The first parameter is invalid, it can not be blank.
            ECHO - Valid value is a number from 1 to 526.
            ECHO - Leading zeros are not valid.
        )
    )

    IF "%~1"=="NAME" (
        ECHO - Value: %NAME%
        IF NOT "%NAME%"=="" SET PASSEDVALIDATION=1
        IF "!PASSEDVALIDATION!"=="0" (
            ECHO - The second parameter is invalid, it can not be blank.
        )
    )

    IF "!PASSEDVALIDATION!"=="0" (
        ECHO - Failed validation.
        EXIT /B 1
    ) ELSE (
        ECHO - Passed validation.
    )
    EXIT /B 0

用法示例：

C:\mytestscript.bat 10 MrTest
Validating NUMCODE...
- Value: 10
- Passed validation.

Validating NAME...
- Value: MrTest
- Passed validation.

C:\mytestscript.bat 600
Validating NUMCODE...
- Value: 600
- The first parameter is invalid, it can not be blank.
- Valid value is a number from 1 to 526.
- Leading zeros are not valid.
- Failed validation.

C:\mytestscript.bat 10
Validating NUMCODE...
- Value: 10
- Passed validation.

Validating NAME...
- Value: 
- The second parameter is invalid, it can not be blank.
- Failed validation.

Answer 9

我使用技术含量更低的方法。它仅适用于整数并支持负值。

set "XVALUE=%~1"
set /A XVALUE=XVALUE
if "%XVALUE%" NEQ "%~1" goto :invalid_value

第一行获取命令行参数并将其放入 XVALUE。使用“引号”可以防止各种特殊字符出现问题。

第二行看起来很神秘，但当 SET /A 等号右侧的文本字符串被解释为包含数值的环境变量时，它利用了这一点。命令处理器解析假定的数值而不生成任何错误消息或设置 ERRORLEVEL。这样做总是会导致 XVALUE 被转换为有效的数值，无论传递给我们什么。

第三行是可选的，仅当您想严格要求参数是 -2147483648 到 2147483647 范围内的数值时才需要。如果您不使用 if 测试，那么

• 您可以通过为八进制和十六进制数字添加前缀 0 或 0x 来支持它们。
• 如果有人使用非常小或非常大的数字，例如 -9999999999999 或 9999999999999，则 XVALUE 将设置为允许的最小值或最大值，即 -2147483648 和 2147483647。
• 如果有人使用诸如“hello”之类的垃圾，则 XVALUE 设置为 0。如果它类似于 123x456，则解析器在“x”处停止，XVALUE 设置为 123。

Answer 10

if errorlevel 只接受可用于检查的数值：

set test_var=001
( 
  (if errorlevel %test_var% break ) 2>nul
)&&(
  echo %test_var% is numeric
)||(
  echo %test_var% is NOT numeric
)

set test_var=001X
( 
  (if errorlevel %test_var% break ) 2>nul
)&&(
  echo %test_var% is numeric
)||(
  echo %test_var% is NOT numeric
)

第一次检查会通过，第二次不会。 虽然上面的脚本不能处理一元 + - 如果你也想处理这种情况，请检查 - isInteger.bat