批处理代码：如何传递从输入列表中选择的参数？

Question

我是这个论坛的新手，所以我希望尊重你的所有规则，如果不是请原谅我！

我刚刚开始研究有关批处理文件的知识，我正在尝试通过批处理传递参数来执行一个简单的程序（最后一个目标是提交一个传递日期参数的 SAS 程序）。

是否可以激活一种列表，我可以在其中选择一些预定义的参数？

-->这是我工作的真正目的

我正在尝试“玩”这段代码：

    @echo off

    title Setting up execution period

    echo Insert your date in the format GGMMMAAAA (es: '31DEC2003'D).

    SET /p data_par=Insert the date to filter datas:

    SET first_byte=%data_par:~1,1%

    if "%first_byte%"=="" (

           GOTO tag1 

    ) else (

           GOTO tag2
)

:tag1
   msg * Missing value

:tag2
   msg * Well done!

pause

我尝试了很多方法，但是似乎没有执行IF语句，我不知道我哪里错了。

另一个问题：为什么在我按“Enter”后提示关闭（执行 set/p 命令后）？

--> 将“暂停”命令放在脚本末尾已解决。

感谢大家的关注，

最好的问候！

Squotty

Answer 1

在代码末尾添加pause 以查看错误消息。

使用else 时if 的正确语法是：

if "a"=="b" (dosomething) else (dosemethingelse)

你可以写成几行，但是有规则，在哪里设置括号：

if "a"=="b" (
  echo this is code for something
  rem more lines possible
) else (
  echo this is code for something else
  rem more lines possible
)

第一个( 必须与if 在同一行。

) else ( 必须在一行。

如果您使用 set /p 按 Enter 键，则变量保持不变（可能为空），因此您的代码将继续输入代码并点击行 else。这里会告诉你“else 不被识别为命令……”

在您的tagx，您应该告诉批处理，在哪里停止执行。使用goto :eof 停止执行或使用goto somewhere 在其他地方继续。如果你不这样做，它将继续下一行。

例子：

:tag1
   msg * Missing value
   goto :eof
:tag2
   msg * Well done!
   goto :continue
pause
:continue
REM go on with the program...

（注意：永远无法到达pause。我让它在那里向您展示事情是如何运作的）

编辑您可以检查格式是否正确，而不仅仅是检查某些输入：

echo %data_par%|findstr /r "[0-3][0-9][A-Z][A-Z][A-Z][1-2]0[0-9][0-9]">nul && (
  echo correct format 
  goto continue
)  || (
  echo wrong format
  goto startover
)

它不是防弹的（例如，38ABC2019 将被视为“正确”），但至少它会检查格式是否正确（例如，15.12.2019 或 12/15/2014 将被视为“不正确”）

Answer 2

@ECHO OFF
SETLOCAL

SET "item1=date1"
SET "item2=date2"
SET "item3=date3"
SET "item4=date4"

FOR /l %%a IN (1,1,4) DO CALL ECHO(%%a. %%item%%a%%
ECHO(U. User-specified
choice /c 1234u
CALL SET selection=%%item%errorlevel%%%
IF NOT DEFINED selection (
 SET /p selection="Your date-selection ? "
)
IF NOT DEFINED selection ECHO No selection made&GOTO :EOF 
ECHO selection is %selection%

GOTO :EOF

此代码可能会有所帮助。

使用批处理窗口开发批处理代码是很正常的。只需设置command prompt 的快捷方式（开始>程序>附件），您就可以一遍又一遍地运行脚本并在屏幕上保留结果，而无需使用“暂停”。可以通过在提示中使用notepad batchfilename.bat 来完成编辑（如果您使用记事本作为编辑器 - 如果使用更好的东西，则替换该程序的名称）。您可以通过执行exit 命令退出批处理窗口。

您还可以使用commandname /? 获得有关批处理命令的帮助 - 它通常很神秘，而且有很多怪癖。此处提供有关 SO 的广泛帮助。