将多行字符串传递给批处理文件

Question

我正在将一个多行字符串从一个 vbscript 传递给一个批处理文件。但是，当我尝试从批处理文件中获取整个字符串时，它只接收第一行。如何让批处理文件知道读取整个字符串，而不是在换行符处停止。

输入：
C:\组件A

C:\组件B

C:\组件C

VBScript：

multstring = "C:\Component_A" + Chr(13) + Chr(10) + "C:\ComponentB" +
       Chr(13) + Chr(10) + "C:\ComponentC" + Chr(13) + Chr(10)

script_path = "runscript.bat """ + multstring + """

Shell(script_path)

批次：

set "scriptargs=%~1"
echo "%scriptargs%"
setlocal enableDelayedExpansion
echo !scriptargs!

我得到的输出：

C:\组件A

想要的输出：

C:\组件A

C:\组件B

C:\组件C

Answer 1

多行字符串不能通过命令行参数传递给批处理文件，但新行可以包含在环境变量中。

VBS可以定义一个带有换行符的环境变量，然后你调用的批处理脚本可以通过延迟扩展读取并显示该值。

test.vbs

set wshShell = CreateObject("WScript.Shell")
set Env=wshShell.Environment("PROCESS")

multstring="C:\Component_A" + Chr(13) + Chr(10) + "C:\ComponentB" + _
            Chr(13) + Chr(10) + "C:\ComponentC" + Chr(13) + Chr(10)

Env("arg1") = multstring

script_path = "runscript.bat arg1"

wshShell.Run script_path

runscript.bat

@echo off
setlocal enableDelayedExpansion
echo !%1!
pause

请注意，这适用于由 VBS 调用的批处理脚本，因为新的批处理脚本继承了 VBS 环境的副本。

如果批处理脚本调用 VBS，则 VBS 无法通过环境变量将值传递回调用方，因为一旦 VBS 结束，VBS 环境就会丢失。

Answer 2

正如 dbenham 提到的，通过引用传递多行字符串是个好主意。

但如果你真的需要按值传递它们这也是可能的。
问题是要访问它们。

这是How to receive even the strangest command line parameters? 的改编变体。

@echo off
setlocal DisableExtensions DisableDelayedExpansion
REM Write the complete parameter to a temp file
@echo on
@(for %%A in (%%A) do (
    @goto :break
    REM # %1 #
    REM
)) > param.tmp
:break
@echo off

REM receive all lines from the temp file and store them in an array
setlocal EnableExtensions
set cnt=0
for /F "skip=3 delims=" %%a in (param.tmp) DO (
    set /a cnt+=1
    setlocal EnableDelayedExpansion
    for /F %%n in ( "!cnt!" ) do (
        setlocal DisableDelayedExpansion
        set "param%%n=%%a"
    )
)
setlocal EnableDelayedExpansion
set \n=^


REM Build the \n variable with a linefeed character, the two empty lines are required

REM Build from the array a single parameter
set /a cnt-=2
set "param1=!param1:~6!"    REM Remove the 'REM #' from the first line
set "param%cnt%=!param%cnt%:~0,-3!" REM Remove the trailing '#' from the last line
set "param="
for /L %%n in (1 1 !cnt!) do (
    if %%n GTR 1 set "param=!param!!\n!"
    set "param=!param!!param%%n:~1!"
)
echo The param is: '!param!'

来自控制台的示例调用（需要空行！）：

test.bat ^"hello^

Line2^

Line3"

无法访问回车，因为它们总是被 cmd.exe 删除

但是当使用次优内容时仍然存在问题。