批处理 - 搜索部分/确切名称并将文本文件中的行复制到批处理中作为 var

Question

以下信息包含在一个文本文件中，格式如下。

/var/www/xxx/html/videos/video_folder_1
/var/www/xxx/html/videos/video_folder_2
/var/www/xxx/html/videos/video_folder_3
/var/www/xxx/html/videos/video_folder_4
/var/www/xxx/html/videos/video_folder_5
/var/www/xxx/html/videos/video_folder_6
/var/www/xxx/html/videos/video_folder_7

我在已经定义的批处理文件中还有一个名为%file_name% 的变量。

所以可以说是%file_name% = V001-video_folder_6.mp4

如您所见，还有更多额外信息，V001- 和 .mp4。

我想使用 var %file_name% 来搜索文本文件并返回整行。在这种情况下，它将返回/var/www/xxx/html/videos/video_folder_6，然后将此信息放入一个新的变量中，比如%folder_path%。

我想我会使用findstr，但是我一直在玩，并没有得到最好的结果。

Answer 1

使用findstr 的方法的问题在于它们很慢，因为它们每次都需要执行findstr.exe（大约30KB 的文件）。一个更简单/更快的解决方案是在array 的帮助下仅使用内部批处理命令。如果要处理的名称数量很大，可能会标记两种方法之间的时间差异。

@echo off
setlocal EnableDelayedExpansion

rem Load the lines from text file into an array with the last part as index:
for /F "delims=" %%a in (test.txt) do (
   set "line=%%a"
   for %%b in (!line:/^= !) do set "lastPart=%%b"
   set "folder[!lastPart!]=%%a"
)

set "file_name=V001-video_folder_6.mp4"

rem Get the folder from file_name:
for /F "tokens=2 delims=-." %%a in ("%file_name%") do set "folder_path=!folder[%%a]!"

echo Folder path is: %folder_path%

Answer 2

让我们假设发布的行在当前工作目录中的文件Test.txt 中。

@echo off
set "file_name=V001-video_folder_6.mp4"
for /F "tokens=2 delims=-." %%A in ("%file_name%") do set "folder=%%A"
for /F "delims=" %%P in ('%SystemRoot%\System32\findstr.exe "/C:%folder%" Test.txt') do (
    set "folder_path=%%P"
    goto NextCommand
)
:NextCommand
echo Full folder path is: %folder_path%

打开命令提示符窗口，输入命令for /?，按RETURN 或ENTER 键并阅读输出帮助以了解这个小代码。

FOR 循环内的命令goto 导致在找到包含感兴趣文件夹路径的第一个行之后立即退出findstr.exe 的循环处理输出。

如果在文本文件中找不到搜索的文件夹，可能会更好：

@echo off
set "file_name=V01-VIDEOS for school (Miss Patrick).mp4"
for /F "tokens=2 delims=-." %%A in ("%file_name%") do set "folder=%%A"
for /F "delims=" %%P in ('%SystemRoot%\System32\findstr.exe "/C:%folder%" Test.txt') do (
    set "folder_path=%%P"
    goto FoundFolder
)
echo "%folder%" not found in file Test.txt.
pause
goto :EOF
:FoundFolder
echo Full folder path is: "%folder_path%"
pause

Answer 3

这应该可行：

::file_name=V001-video_folder_6.mp4
::file containing folder paths is called paths.txt

for /f "tokens=2 delims=-." %%a in ("%file_name%") do set FN=%%a
for /f %%a in ('findstr /E /L "%FN%" "paths.txt"') do set folder_path=%%a
echo %folder_path%

你想要的实际上是两行。