批处理文件中的递归for循环而不遵循符号链接

Question

除了不遵循符号链接之外，在批处理文件中是否有一种简单的方法来循环包括子目录在内的文件（如下所示）？

FOR /R %%F IN (*) DO (...)

我在for帮助中没有看到这样的标志...

上下文是我正在编写一个循环文件​​并创建符号链接的批处理文件。它需要通过子目录，但是当有针对目录的符号链接时，它不应该通过它们。对于我当前的FOR /R 循环实现，问题在于它将此类符号链接视为子目录并在其目标内容中运行脚本。我不在乎解决方案是否排除指向普通文件的符号链接（而不是 dirs）。

感谢您的帮助

编辑澄清：

例如，提供这个目录结构：

dir
 |-- A.txt
 |-- subDir
 |     |-- B.txt
 |-- linkDir = symlink to targetDir
 |-- Z.txt = symlink to targetDir/C.txt

targetDir
 |-- C.txt

当我在dir 上运行FOR /R 循环时，它会按预期处理A.txt 和B.txt，但也会处理我不想要的C.txt。这是因为FOR /R 指令在构建要迭代的文件列表时遵循符号链接，因此它就像linkDir 是一个包含C.txt 的常规子目录。

关于Z.txt，循环是否读取它并不重要。 FOR /R 实现实际上会处理它，但我设置了一个过滤器以在 %%F 是符号链接时跳过迭代。

问题是我不知道如何告诉FOR 不要将C.txt 包含在列表中，也不知道当%%F 是targetDir\C.txt 时如何知道该文件在列表中，因为它遵循符号链接在路径dir\subDir\C.txt。

Answer 1

您可以编写自己的递归函数，检查每个文件/目录的链接。
这有点慢，因为每个文件/目录都有%%~aX 访问权限。

@echo off

call :recurseDir .
exit /b

:recurseDir
rem echo ----- :recurseDir "%~1" -------
setlocal EnableDelayedExpansion
pushd "%~1"
FOR /F "delims=" %%X in ('dir /b') DO (
    set "attr=%%~aX"

    if "!attr:~8,1!" NEQ "l" (
        if "!attr:~0,1!" EQU "d" (
            call :recurseDir "%%~fX"
        ) ELSE (
            call echo :processFile "%%~fX"
        )
    )
)
popd

为了加快速度，您可以拆分文件和目录的逻辑。
然后只需要检查带有%%~aX 的目录中的符号链接。
此版本不再需要延迟扩展，因为它通过将字符 l 处的属性拆分为 d-------l-- 来检测符号链接。
因为 Win 7 只显示d-------l，所以必须在属性上附加至少一个虚拟字符（我选择#）

@echo off

call :recurseDir .
exit /b

:recurseDir
echo ----- :recurseDir "%~1" -------
pushd "%~1"
FOR /F "delims=" %%X in ('dir /b /a:-l-d 2^> nul') DO (
    call echo :processFile "%%~fX"
)
FOR /D %%X in (*) DO (  
    set "symlink="
    for /F "tokens=2 delims=l" %%A in ("%%~aX #") DO set "symlink=1"
    if not defined symlink (
        call :recurseDir "%%~fX"
    )
)
popd

Answer 2

试试：

@echo off
setlocal EnableDelayedExpansion

for /R /D %%f in (*) do (
   set "attr=%%~Af"
   if "!attr:~8,1!" neq "l" (
      echo Files in this not-symlink dir:
      dir /B /A:-D "%%f"
   )
)