如何修改此脚本以适应不同的情况？

Question

我编写了一个 VBA 脚本，它在一个列中搜索字符串并在另一列中返回匹配项。重点是按 SKU 将商品编号与其产品图片相匹配。问题是，如果项目编号和图像的大小写不同，则会失败。脚本如下：

Sub Test()
    Dim NA As Long, NC As Long, v As String, I As Long, J As Long
    Dim v2 As String
    NA = Cells(Rows.Count, "A").End(xlUp).Row
    NC = Cells(Rows.Count, "C").End(xlUp).Row
    For I = 2 To NA
        v = Cells(I, "A").Value
        v2 = ""
        For J = 2 To NC
            If InStr(Cells(J, "C").Value, v) > 0 Then
                v2 = v2 & ";" & Cells(J, "C").Value
            End If
        Next J
        Cells(I, "A").Offset(0, 1).Value = Mid(v2,2)
    Next I
End Sub

我如何解释不同的情况？有这个方法吗？

Answer 1

很简单，只需将其转换为小写即可：

Sub Test()
    Dim NA As Long, NC As Long, v As String, I As Long, J As Long
    Dim v2 As String
    NA = Cells(Rows.Count, "A").End(xlUp).Row
    NC = Cells(Rows.Count, "C").End(xlUp).Row
    For I = 2 To NA
        v = LCase(Cells(I, "A").Value)
        v2 = ""
        For J = 2 To NC
            If InStr(LCase(Cells(J, "C").Value), v) > 0 Then
                v2 = v2 & ";" & Cells(J, "C").Value
            End If
        Next J
        Cells(I, "A").Offset(0, 1).Value = Mid(v2,2)
    Next I
End Sub

我刚刚获取了您的代码示例，并将 v 和 Cells(J, "C").Value 的强制转换为小写。

我没有对此进行测试，所以我不能保证完美的功能。

---

你也可以改变你的模块（在顶部）

Option Compare Text

这将完全关闭区分大小写（因此您不需要LCase(..)）

Answer 2

只需使用Instr function 的vbTextCompare 选项即可。

If InStr(1, Cells(J, "C").Value, v, vbTextCompare) > 0 Then
    v2 = v2 & ";" & Cells(J, "C").Value
End If

[vbTextCompare] 根据应用程序当前文化信息确定的不区分大小写的文本排序顺序执行文本比较。