无法在 Jenkins Pipeline 中显示 JUnit 测试结果

Question

我有一段 Jenkins 管道代码，我试图在我的角度代码上运行 JUnit。

如果单元测试失败，Jenkins 必须停止流水线。 除了我看不到“最新测试结果”和“测试结果趋势”之外，它正在工作

我正在使用 Jenkins 2.19.1、Jenkins Pipeline 2.4 和 Junit 1.19。这是管道代码：

{
        sh("npm install -g gulp bower")
        sh("npm install")
        sh("bower install")    
        try {
            sh("gulp test")
        } catch (err) {
            step([$class: 'JUnitResultArchiver', testResults: '**/reports/junit/*.xml', healthScaleFactor: 1.0])
            junit '**/reports/junit/*.xml'
            if (currentBuild.result == 'UNSTABLE')
                currentBuild.result = 'FAILURE'
            throw err
        }
    }

知道我做错了什么吗？

Answer 1

如果您使用声明式管道，您可以执行以下操作：

pipeline {
   agent any
   stages {
     stage('Build and Test') {
        steps {
            sh 'build here...'
            sh 'run tests here if you like ...'
        }
     }
   }
   post {
      always {
        junit '**/reports/junit/*.xml'
      }
   } 
}

这也可以与 html 发布或任何东西一起使用，不需要 finally/catch 等。它将始终存档结果。

请参阅https://jenkins.io/doc/book/pipeline/syntax/#declarative-pipeline 了解更多信息。

如果你有一个 clean 目标导致没有测试输出：

  post {
    always {
      junit(
        allowEmptyResults: true,
        testResults: '**/test-reports/*.xml'
      )
    }

Answer 2

用于发布由 Gradle 构建生成的 JUnit 样式测试结果的 Jenkins 流水线步骤：

  stage('Publish test results') {
      steps {
          junit '**/test-results/test/*.xml'
      }
  } 

Answer 3

我认为我以前尝试做的方式是错误的。我已经改变了我的代码，如下所示，它可以工作：

{
        sh("npm install -g gulp bower")
        sh("npm install")
        sh("bower install")
        try {
            sh("gulp test")
        } catch (err) {
            if (currentBuild.result == 'UNSTABLE')
                currentBuild.result = 'FAILURE'
            throw err
        } finally {
            step([$class: 'JUnitResultArchiver', testResults: '**/reports/junit/*.xml', healthScaleFactor: 1.0])
            publishHTML (target: [
                    allowMissing: false,
                    alwaysLinkToLastBuild: false,
                    keepAll: true,
                    reportDir: 'coverage',
                    reportFiles: 'index.html',
                    reportName: "Junit Report"
            ])
        }
    }