VBScript - 通过 cmd.exe 创建具有用户定义名称和扩展名的文件

Question

对缺少缩进表示歉意。问题是双重的，并且特定于代码的最后一行。 首先，我似乎无法让 %username% 在其上下文中工作......其次是“。& ext”。我尝试输入完整的目标文件夹地址，但无济于事；并尝试为点扩展添加包络引号，但再次无济于事...我对 CMD 有一些经验，但对 VBS 很少...任何帮助表示赞赏！

dim name, app, ext

do
name = inputbox ("Please enter file name", "Make File")
if name = "" then
wscript.quit ()
end if
loop until name <> ""

do while (ext = "")
app = inputbox ("Please enter related application", "Make File")
if app = "" then
wscript.quit ()
elseif lcase(app) = "notepad" then
ext = "txt"
elseif lcase(app) = "word" then 
ext = "doc"
elseif lcase(app) = "excel" then
ext = "xml"
elseif lcase(app) = "powerpoint" then
ext = "ppt"
else
msgbox("Application not recognised")
end if
loop

msgbox "File created in desktop folder"

set objshell = createobject("wscript.shell")
objshell.run "cmd /c echo. > c:\Users\%username%\Desktop\" & name . & ext

Answer 1

首先，在您的示例中，您的代码最后一行的句号周围缺少一些引号，但我怀疑这只是一个错字，因为它可能仍然无法正常工作。你需要像这样双引号：

objshell.run "cmd /c echo. > ""c:\Users\%username%\Desktop\" & name &"." & ext & """"

鉴于桌面文件夹是一个“特殊”文件夹，最好不要尝试以您在此处尝试的方式枚举该文件夹 - 在某些环境中，用户配置文件会重新映射到其他地方。

相反，您可以像这样修改代码的最后几行：

msgbox "File created in desktop folder"
set objshell = createobject("wscript.shell")
desktopFolder = objShell.SpecialFolders("Desktop")                    ' This will get you the desktop folder location...

objshell.run "cmd /c echo. > """& desktopfolder & "\" & name & "." & ext & """"     ' This is messy, but it will likely work.

或者，您可以将整个代码替换为以下示例。您可以使用 case 语句，而不是使用令人困惑的 elseif 代码，而且我不确定您是否知道，但是如果您在 IF 语句上只有一个条件，您可以在同一行键入它们（请参阅下面的例子）。

此外，鉴于您已经在 VBS 中，您还不如使用 vb 命令创建文件，而不是运行 CMD...。因此，您无需使用 cmd /c echo 行可以使用这样的东西：

 Set objFile = objFSO.CreateTextFile(desktopfolder & "\" & Name & "." & Ext,True)

无论如何，这里有另一个版本的脚本应该适合您。 祝你今天过得愉快 ！ :)

---

修订版

Option Explicit                     
Dim Name, App, Ext
Dim objShell, objFSO, desktopFolder, objFile

Do
   Name = inputbox ("Please enter file name", "Make File")
   if Name = "" Then Wscript.Quit ()
Loop until Name <> ""

Do 
   App = inputbox ("Please enter related application", "Make File") 
   If App = "" Then Wscript.Quit ()
   Select Case (LCase(App))
   Case "notepad"
      Ext = "txt"
   Case "word"
      Ext = "doc"
   Case "excel"
      Ext = "xml"
   Case "powerpoint"
      Ext = "ppt"
   Case else    
      msgbox("Application not recognised")
      App = ""
   End Select
Loop Until App <> ""

set objShell = Createobject("wscript.shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
desktopFolder = objShell.SpecialFolders("Desktop")

Set objFile = objFSO.CreateTextFile(desktopfolder & "\" & Name & "." & Ext,True)
objFile.Close

msgbox "File created in desktop folder"