如何知道节点 x 是否具有节点 z 的每个实例，其中它与另一个节点 y 有很多关系，而另一个节点 y 与另一个节点 z 有一个关系？

Question

所以我有一个节点:Customer，它有很多节点:Order，而:Order 必须与节点:Shipper 有1 个关系，称为:SHIP_VIA，这是层次结构：

(customer:Customer)-[:PURCHASED]->(order)-[:SHIP_VIA]->(shipper:Shipper)

现在只有 3 个托运人，订单指向他们，一个客户会有很多订单。所以我的问题是如何让所有客户都与所有托运人一起发货？请注意，每个托运人都有一个shipperID 属性。这是我的代码，但它不工作，除非有一个“存在”

match (customer:Customer)-[:PURCHASED]->(order)-[:SHIP_VIA]->(shipper:Shipper) 

WHERE exists((customer)-[:PURCHASED]->(order)-[:SHIP_VIA]->(:Shipper 

{shipperID:1})) and exists((customer)-[:PURCHASED]->(order)-[:SHIP_VIA]->

(:Shipper {shipperID:2})) and exists((customer)-[:PURCHASED]->(order)-

[:SHIP_VIA]->(:Shipper {shipperID:3})) return  customer, order , shipper;

Answer 1

使用collect() 和all() 函数尝试此解决方案：

// match all shippers
match (shipper:Shipper)
// create a list containing all shippers and pass to the next context
with collect(shipper) as shippers

// match all customers which has purchased an order with each shipper
match (customer:Customer)
where all (shipper in shippers where (customer)-[:PURCHASED]->(:Order)-[:SHIP_VIA]->(shipper))

// return customers
return customer

Answer 2

1. 计算托运人总数
2. 对于每个客户，验证唯一托运人的数量是否等于托运人的总数

---

MATCH (shipper:Shipper) 
WITH count(shipper) AS totalShippers

MATCH (customer:Customer)-[:PURCHASED]->(order)-[:SHIP_VIA]->(shipper:Shipper)
WITH totalShippers, customer, 
     COUNT(DISTINCT shipper) as shippers WHERE totalShippers = shippers

RETURN customer