如何在neo4j中获取特定节点的所有子节点

Question

我在我的 neo4j 中有这种关系：

Parent -> Childs
F -> D,E
D -> A,B,C

用例：我正在尝试使用此查询获取特定节点的所有子节点

MATCH (p:Person{name:"F"})<-[:REPORTS_TO*]-(c) 
RETURN {parent : p.name, child : {name :collect( c.name)}}

这返回给我这个：

{"parent":"F","child":{"name":["D","A","B","C","E"]}}

A, B, C 不是 F 的直接子代，因为它们是 D 的子代

要求的回应是

[
"F" : [ Childs i.e "E", "D" ]
"E" : []
"D" : [ "A", "B", "C" ]
 and so on ....
]

实现此目的的一种方法是递归触发以下查询：

MATCH (p:Person{name:"F"})<-[:REPORTS_TO]-(c) 
RETURN {parent : p.name, child : {name :collect( c.name)}}

返回

{"parent":"F","child":{"name":["E","D"]}}

然后搜索E and D 的所有孩子，然后搜索孩子的孩子等等..

我的问题是我可以通过单个查询还是以更好的方式实现这一目标？

Edit1：添加数据集

CREATE (f:Person {name: "F"})
CREATE (e:Person {name: "E"})
CREATE (d:Person {name: "D"})
CREATE (c:Person {name: "C"})
CREATE (b:Person {name: "B"})
CREATE (a:Person {name: "A"})
CREATE (x:Person {name: "X"})
CREATE (a)-[:REPORTS_TO]->(x)
CREATE (d)-[:REPORTS_TO]->(a)
CREATE (d)-[:REPORTS_TO]->(b)
CREATE (d)-[:REPORTS_TO]->(c)
CREATE (f)-[:REPORTS_TO]->(d)
CREATE (f)-[:REPORTS_TO]->(e)

Answer 1

您可以使用OPTIONAL MATCH 来实现您的目标。

您的数据集如下所示：

试试看：

MATCH (p:Person)
OPTIONAL MATCH (p)<-[:REPORTS_TO]-(c) 
RETURN {parent : p.name, child : {name :collect( c.name)}}

查询结果：

+-----------------------------------------------------+
| {parent : p.name, child : {name :collect( c.name)}} |
+-----------------------------------------------------+
| {parent=D, child={name=[C, B, A]}}                  |
| {parent=A, child={name=[]}}                         |
| {parent=C, child={name=[]}}                         |
| {parent=F, child={name=[E, D]}}                     |
| {parent=E, child={name=[]}}                         |
| {parent=B, child={name=[]}}                         |
+-----------------------------------------------------+

如果您只需要特定的父母和您各自的孩子，您可以这样做：

MATCH (p:Person)
WHERE p.name = "D"
OPTIONAL MATCH (p)<-[:REPORTS_TO]-(c) 
WITH COLLECT (c) + p AS all
UNWIND all as p
MATCH (p)
OPTIONAL MATCH (p)<-[:REPORTS_TO]-(c) 
RETURN {parent : p.name, child : {name :collect( c.name)}}

结果：

+-----------------------------------------------------+
| {parent : p.name, child : {name :collect( c.name)}} |
+-----------------------------------------------------+
| {parent=D, child={name=[C, B, A]}}                  |
| {parent=A, child={name=[]}}                         |
| {parent=C, child={name=[]}}                         |
| {parent=B, child={name=[]}}                         |
+-----------------------------------------------------+

编辑：

来自@Prakash Pandey 的评论：

我们怎样才能在哪里做像孩子、孩子的孩子等等这样的事情 p.name = "汤姆"

根据题中添加的数据集，可以这样做：

MATCH (p:Person)<-[:REPORTS_TO*]-(c:Person)
WHERE p.name = "X"
WITH COLLECT (c) + p AS all UNWIND all as p
MATCH (p)<-[:REPORTS_TO]-(c)
RETURN {parent : p.name, child : {name :collect( c.name)}}

结果：

+-----------------------------------------------------+
| {parent : p.name, child : {name :collect( c.name)}} |
+-----------------------------------------------------+
| {parent=D, child={name=[F]}}                        |
| {parent=A, child={name=[D]}}                        |
| {parent=X, child={name=[A]}}                        |
+-----------------------------------------------------+

Answer 2

我创建了你描述的图表。

以下查询返回您需要的大部分内容：

MATCH (a:Parent)<-[r:isParent*0..]-(b:Parent)
return {parent:a.name,child : {name :collect( b.name)}}

结果：

{"父":"D","子":{"name":["D","A","B","C"]}}

{"父":"A","子":{"name":["A"]}}

{"父":"C","子":{"name":["C"]}}

{"父":"F","子":{"name":["F","D","E","A","B","C"]}}

{"父":"E","子":{"name":["E"]}}

{"父":"B","子":{"name":["B"]}}