Power BI 度量中的行和列内容？

Question

我正在尝试使用 PowerBI 复制最初在 Excel 中进行的计算，虽然我已经阅读了一些关于度量中的上下文计算的文档，但我很难得到结果。

我的桌子想要如下一张

Date	Weight	Calculated_measure
01/01/2020	1	0
01/02/2020	3	31
01/03/2020	3	147

日期以 dd/mm/yyyy 为单位。

计算度量的想法如下：

1. 对于每一行，我将当前“日期”值与所有其他“日期”值进行比较并进行减法。
2. 如果减法的结果大于零，我保留结果。否则，我将结果设置为 0。
3. 然后我将结果乘以权重

为了说明第三行的计算： (01/03/2020-01/01/2020)*1 + (01/03/2020-01/02/2020) *3 + (01/03/2020-01/03/2020) *2 =60 *​​ 1 + 29 * 3 + 0 = 147

Excel 中第一行的公式，例如： = { SUMPRODUCT(
如果 ( (A2-$A$2:$A$4)>0; (A2-$A$2:$A$4); 0 ) ; $B$2:$B$4 ) }

谢谢。理解这段代码对我学习 PowerBI 中的上下文过滤器有很大帮助

Answer 1

DAX 中令人困惑的一点是如何知道要使用哪个行上下文。

您可以使用 EARLIER 函数从 sumproduct 行上下文移回之前的原始行上下文，并像这样定义您的度量：

CALCULATED_COLUMN = 
SUMX (
    Table1,
    IF (
        EARLIER ( Table1[DATE] ) > Table1[DATE],
        EARLIER ( Table1[DATE] ) - Table1[DATE]
    ) * Table1[WEIGHT]
)

如果您不想记住 EARLIER 的工作原理，可以使用变量将原始行上下文定义为常量并在迭代器中使用：

CALCULATED_COLUMN = 
VAR RowDate = Table1[DATE]
RETURN
    SUMX (
        FILTER ( Table1, Table1[Date] < RowDate ),
        ( RowDate - Table1[DATE] ) * Table1[WEIGHT]
    )

在上面，我应用了过滤器而不是使用 IF。如果适用，这通常会更有效。

---

编辑：在上面，我在考虑计算列。作为衡量标准，情况略有不同，以下 OP 的评论是适当的调整：

MEASURE =
VAR RowDate = SELECTEDVALUE ( Table1[DATE] )
RETURN
    SUMX (
        FILTER ( ALL ( Table1 ), Table1[Date] < RowDate ),
         ( RowDate - Table1[Date] ) * Table1[WEIGHT]
    )

SELECTEDVALUE 是必需的，因为度量值不存在行上下文，并且需要 ALL 才能将 sum-product 应用于整个表，而不仅仅是过滤器上下文中的部分。