从值表中创建值列表并排除某些值答案

【问题标题】：Create a list of values from a table of values and exclude certain values从值表中创建值列表并排除某些值
【发布时间】：2018-09-29 08:56:08
【问题描述】：

我有以下 Excel 电子表格：

    A            B       C        D        E              F                 G    
1                 Q1     Q2       Q3      Q4        Positive values
2   Asset 1      -50     85      -90      70             85 
3   Asset 2      -28    -80      -45      60             70         
4   Asset 3      -30     50       55     -10             60      
5   Asset 4      -20      5      -80     -15              :  
6   Asset 5       35    -30       27     -98              :
7

在单元格A1:E6 中，我有不同的资产，它们在季度Q1-Q4 的表现。

在Column F 中，我使用here 中的公式创建了资产的所有积极表现的列表：

Column F = {LARGE(IF($B$2:$E$6>0,B$2:$E$6),ROW(B1:E1))}

到目前为止，这一切都很好。

但是，现在我想从Column F 的列表中排除某些值。例如，我不希望该号码 85 或号码 70 出现在列表中。因此，我尝试将公式修改为：

Column F = {LARGE(IF(AND($B$2:$E$6>0,$B$2:$E$6<>85,$B$2:$E$6<>70),B$2:$E$6),ROW(B1:E1))}

但是，现在我得到 0 作为结果。

您有任何可以解决此问题的公式的想法吗？

【问题讨论】：

您可以使用AutoFilter 排除某些值。

标签： excel excel-formula

【解决方案1】：

创建一个由 0 组成的数组，其中 0 等于负数或排除值

($B$2:$E$6>0)*($B$2:$E$6<>85)*($B$2:$E$6<>70)

1/(... 会将其转换为 1 和错误
乘以原始值以创建原始值和错误数组

 =1/(($B$2:$E$6>0)*($B$2:$E$6<>85)*($B$2:$E$6<>70)) * B2:E6

使用聚合函数得到你想要的结果

=AGGREGATE(14,6,1/(($B$2:$E$6>0)*($B$2:$E$6<>85)*($B$2:$E$6<>70))*$B$2:$E$6,ROWS($1:1))

填写以获取第二、第三等最大的

【讨论】：

【解决方案2】：

你走在正确的道路上。而不是使用AND，嵌套的IF 可以工作。您需要为要测试的每个新条件创建一个新的IF 标准。所以如果要排除 85 和 70 则需要添加两个额外的 IF 语句。

F 列的公式为：

={LARGE(IF($B$2:$E$6>0,IF($B$2:$E$6<>85,IF($B$2:$E$6<>70,B$2:$E$6))),ROW(B1:E1))}

你可以在这里阅读公式的过程是怎样的：Minimum if multiple criteria

【讨论】：

非常感谢。完美运行。

【解决方案3】：

如果您在 F 列中有数据，并且您希望将所有不是 70 或 85 的值提取到列 G ，然后在 G2 中输入：

=IFERROR(INDEX(F$2:F$9999, AGGREGATE(15, 6, ROW($1:$999)/((F$2:F$9999<>85)*(F$2:F$9999<>70)), ROW(1:1))),"")

并向下复制：

请注意，这种方法不需要使用数组公式。

【讨论】：