如何修改或读取作为函数参数传递的可变向量？

Question

  test :: VM.MVector s Int -> Int
  test x = runST $ do
    a <- return x
    VM.read a 0 -- Type error

我试图弄清楚如何不将 ST monad 中的所有内容放入单个函数中。如果我试图修改x 或从中返回一个值，编译器会抱怨可变向量的状态部分不匹配。

是否可以在 Haskell 中对传递的可变向量进行操作，还是我必须在对它们进行任何操作之前将它们冻结为不可变的对应物？

编辑：

这是实际的错误。

Couldn't match type `s1' with `s'
  `s1' is a rigid type variable bound by
       a type expected by the context: ST s1 Int at rjb.hs:17:12
  `s' is a rigid type variable bound by
      the type signature for test :: VM.MVector s Int -> Int
      at rjb.hs:16:11
Expected type: VM.MVector
                 (Control.Monad.Primitive.PrimState (ST s1)) Int
  Actual type: VM.MVector s Int
Relevant bindings include
  a :: VM.MVector s Int (bound at rjb.hs:18:5)
  x :: VM.MVector s Int (bound at rjb.hs:17:8)
  test :: VM.MVector s Int -> Int (bound at rjb.hs:17:3)
In the first argument of `VM.read', namely `a'
In a stmt of a 'do' block: VM.read a 0

编辑：以下通过类型检查。

  test :: VM.MVector (Control.Monad.Primitive.PrimState IO) Int -> IO (Int)
  test x = VM.read x 0

我猜我也可以改变x 向量。所以……

Answer 1

你可能需要一些例子。这是一个基本的评论，但如果你谷歌一下，我相信你会在网上找到其他人。

import Control.Monad.ST
import qualified Data.Vector.Mutable as VM

-- This returns a reference to a vector, wrapped in the ST s monad.
test :: ST s (VM.MVector s Int)
test = do
  v <- VM.new 10       -- create vector
  VM.write v 3 2000    -- modify it
  VM.write v 4 3000
  x <- VM.read v 3     -- access it
  VM.write v 4 (x+1)   
  return v             -- return it

-- This instead returns a (wrapped) Int
test2 :: ST s Int
test2 = do
  v <- test            -- call test, which performs the allocation
  VM.read v 4          -- return v[4]

-- This returns a plain pure Int value    
test3 :: Int
test3 = runST test2

请注意，runST x 只能在 x 的类型为 polytype ST s T 其中T 不涉及类型变量s。 这就是 ST monad 实现引用透明性的方式。

用更简单的术语来说，这意味着runST 绝不能返回任何指向已分配内存的“指针”。当runST 返回时，可以释放可变事物的每个分配。因此，典型的ST s 计算仅在最后执行runST，当它准备好丢弃所有可变数据并保留其中的不可变部分时。在上面的示例中，不可变部分是第 4 个元素（照常从 0 开始计数），即不可变的 Int。

如果您不熟悉ST s，我建议您暂时忘记向量，并使用STRef s Int（参考Int）和ST 进行一些练习。任何ST 教程就足够了。