使用条件将每个单词的首字母大写

Question

我有一个类似于VENDOR CORPORATION (GA/ATL) 的文本。我想让它看起来像Vendor Corporation (GA/ATL)。

所以，除了( 和) 之间存在的单词之外，我只想将每个单词的第一个字母大写。

我遇到了 - UPPER(LEFT(FIELD_NAME,1))+LOWER(SUBSTRING(FIELD_NAME,2,LEN(FIELD_NAME)))，但它一次只能处理一个单词，并且没有我想要的功能。最需要一个可以完成这项工作的功能。

Answer 1

尝试像这样使用function：

BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 1

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                         ELSE SUBSTRING(@InputString, @Index - 1, 1)
                    END

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    BEGIN
        IF  @PrevChar != '(' AND @PrevChar != '/'
            SET @OutputString = STUFF(@OutputString, @Index, 1, UPPER(@Char))
        IF  @PrevChar = '(' 
            SET @OutputString = LEFT(@OutputString, LEN(@OutputString) - LEN(SUBSTRING(@OutputString, CHARINDEX('(',@OutputString), CHARINDEX(')',@OutputString)))) +  UPPER(SUBSTRING(@OutputString, CHARINDEX('(',@OutputString), CHARINDEX(')',@OutputString)))
    END

    SET @Index = @Index + 1
END

RETURN @OutputString

END

用法

SELECT [dbo].[InitCap]('VENDOR CORPORATION (GA/ATL)')

输出

Vendor Corporation (GA/ATL)

Answer 2

作为上述答案的替代方案。如果您只想忽略( 和) 之间的内容，您可以使用InitCap 函数的略微修改版本

CREATE FUNCTION [dbo].[InitCap] (
     @InputString VARCHAR(4000)
    )
RETURNS VARCHAR(4000)
AS 
    BEGIN

        DECLARE @Index INT
        DECLARE @Char CHAR(1)
        DECLARE @PrevChar CHAR(1) = ' '
        DECLARE @OutputString VARCHAR(255)
        SET @OutputString = LOWER(@InputString)
        SET @Index = 1
        WHILE @Index <= LEN(@InputString) 
            BEGIN
                SET @Char = SUBSTRING(@InputString,@Index,1)
                IF @Char = '(' 
                    BEGIN
                        WHILE @Index <= LEN(@InputString)
                            AND @Char NOT IN (')') 
                            BEGIN 
                                SET @Index = @Index + 1
                                SET @PrevChar = @Char
                                SET @Char = SUBSTRING(@InputString,@Index,1)
                                SET @OutputString = STUFF(@OutputString,@Index,1,@Char)
                            END
                    END              
                IF @PrevChar IN (' ',';',':','!','?',',','.','_','-','/','&','''') 
                    BEGIN
                        IF @PrevChar != ''''
                            OR UPPER(@Char) != 'S' 
                            SET @OutputString = STUFF(@OutputString,@Index,1,UPPER(@Char))
                    END
                SET @Index = @Index + 1
                SET @PrevChar = @Char
            END
        RETURN @OutputString
    END
GO

示例

SELECT  [dbo].[InitCap](n)
FROM    ( VALUES ( 'VENDOR CORPORATION (GA/ATL)'), 
                 ( 'VENDOR CORPORATION (ga/atl)'), 
                 ( 'VENDOR CORPORATION (Ga/Atl)') ) t (n)

output
--------
Vendor Corporation (GA/ATL)
Vendor Corporation (ga/atl)
Vendor Corporation (Ga/Atl)

如果您总是想在 ( 和 ) 中使用大写字母，只需在这两个地方使用 SET @OutputString = STUFF(@OutputString,@Index,1,UPPER(@Char))

Answer 3

使用 Jeff Moden 分离器（可在此处找到。http://www.sqlservercentral.com/articles/Tally+Table/72993/）可以完成此操作。然后，您需要使用交叉表（也称为条件聚合）将片段重新组合在一起。您也可以使用 PIVOT 执行此操作，但我发现交叉表的语法不那么钝，并且已被证明在性能方面稍快一​​些。这也使用了此处的 InitCap 函数。 How to update data as upper case first letter with t-sql command?

declare @Value varchar(100) = 'VENDOR CORPORATION (GA/ATL)';

with sortedValues as
(
    select Case when left(s.Item, 1) = '(' then s.Item else dbo.InitCap(s.Item) end as CorrectedVal
        , s.ItemNumber
    from dbo.DelimitedSplit8K(@Value, ' ') s
)

select MAX(case when ItemNumber = 1 then CorrectedVal end) + ' '
     + MAX(case when ItemNumber = 2 then CorrectedVal end) + ' '
     + MAX(case when ItemNumber = 3 then CorrectedVal end)
from sortedValues

如果您不提前知道您将拥有多少“单词”，您可以将此交叉表调整为动态版本。您可以在此处阅读有关动态交叉表的更多信息。 http://www.sqlservercentral.com/articles/Crosstab/65048/

--编辑--

感谢 JamieD77 提出使用 STUFF 的建议。我特别喜欢这个选项，因为我有另一个使用计数表的 InitCap 版本，而不是这里引用的使用 while 循环的版本。使用 STUFF 有助于将整个事情变成内联表值函数，因此它会非常快。如果有人想在不循环的情况下查看 InitCap，请告诉我，我很乐意发布。

这是使用建议的 STUFF 方法的查询。

SELECT STUFF((SELECT   ' ' + s.CorrectedVal
    FROM sortedValues s
    ORDER BY s.ItemNumber
    FOR
    XML PATH('')
    ),1,1,'')