具有两种不同规格的 Gnuplot 自定义图例

Question

我想要 gnuplot 中的一个键，它与每条绘制的线无关，而是代表每条线的规格。

基本上我想要的是键中的三条彩色线来代表我正在使用的三种算法。然后用三个形状来表示每种算法的误差范围。

所以我的钥匙看起来像这样：

红线——alg 1

蓝线 -- alg 2

绿线——alg 3

三角形 -- 5%

圆 -- 3%

正方形 -- 1%

我的图表中有 9 条线，它们是颜色和形状的组合，但我不希望我的图例包含所有 9 条线，而只是代表规格。

我希望这是有道理的。如果您需要更多说明，请告诉我。

我还没有找到很多资源来制作一个独立于我的绘图线的键，所以我只知道为每一行设置“notitle”。

Current graph

Answer 1

实现这一点的一个简单方法是在没有键的情况下绘制数据（“键”是 gnuplot 术语，您称之为“图例”），然后制作没有数据的键。这样，无论绘制的数据系列的数量和样式如何，键都可以包含您想要的任何内容。我将其称为“假密钥”，因为它是一个密钥，但由于它不是直接从可见数据系列生成的，因此具有故意欺骗性。

使用“假键”绘图

首先，绘制您的数据并（就像您推测的那样）使用notitle 关键字，这样该数据就不会出现在键中。然后，使用NaN（不是数字）作为数据绘制任何内容。您可以根据需要为其命名、指定点类型、线型等。因为他们有一个title，所以他们会以您给定的标题显示在键中，而真实数据（带有notitle）则不会。

例如，我使用您的键规范绘制了一个图，但绘制了我自己的线：

set terminal pngcairo size 640,480 enhanced
set output "example.png"
set title "Plot with a False Key"

# Some line styles
set style line 1 lc rgb "red" lt 1
set style line 2 lc rgb "blue" lt 1
set style line 3 lc rgb "green" lt 1

# Some dummy things to plot
set xrange [-4*pi:4*pi]
set yrange [-0.3:1.1]
f1(x) = exp(-x**2/2)
f2(x) = sin(x)/x
f3(x) = 0.5*sin(2*x)/x

# First plot data with 'notitle', then make a false key with NaN
plot f1(x) ls 1 notitle, f2(x) ls 2 notitle, f3(x) ls 3 notitle, \
     NaN ls 1 title "Alg. 1", NaN ls 2 title "Alg. 2", NaN ls 3 title "Alg. 3", \
     NaN with points pt 9 lc rgb "black" title "5% error", \
     NaN with points pt 7 lc rgb "black" title "3% error", \
     NaN with points pt 5 lc rgb "black" title "1% error"

请注意我是如何预先定义线条样式的。这是为了帮助保持绘制的数据（例如f1(x) ls 1 notitle）与密钥中的内容（例如NaN ls 1 title "Alg. 1"）保持同步。这样，线型规范在代码中只出现一次。要更改它，您只需在一处更改即可。

还要注意键中的虚拟点形状是如何绘制的with points 和使用lc rgb "black"。将它们设为黑色表明它们与算法行的红色/绿色/蓝色无关。这是为了向观看者建议形状代表与颜色不同的参数。

线条风格合理性建议

您的示例图有九个数据系列。您可以尝试预先指定线条样式，例如：

# Colors and point types to use
alg1_color = "red"
alg2_color = "blue"
alg3_color = "green"
err5_pt = 9  # pt 9 = triangle
err3_pt = 7  # pt 7 = circle
err1_pt = 5  # pt 5 = square

# Algorithm 1 lines
set style line 1 lc rgb alg1_color lt 1 pt err5_pt
set style line 2 lc rgb alg1_color lt 1 pt err3_pt
set style line 3 lc rgb alg1_color lt 1 pt err1_pt

# Algorthm 2 lines
set style line 4 lc rgb alg2_color lt 1 pt err5_pt
set style line 5 lc rgb alg2_color lt 1 pt err3_pt
set style line 6 lc rgb alg2_color lt 1 pt err1_pt

# Algorthm 3 lines
set style line 7 lc rgb alg3_color lt 1 pt err5_pt
set style line 8 lc rgb alg3_color lt 1 pt err3_pt
set style line 9 lc rgb alg3_color lt 1 pt err1_pt

当您绘制数据时，只需将 ls 4 用于 Alg。 2 (5%)，ls 9 用于算法。 3 (1%) 等。您的颜色和点类型只定义在一个地方，更容易更改和保持一致。

另一个建议：如果有人试图打印你的情节，那么在黑白打印时很难区分红色、绿色和蓝色。如果您为不同的算法类型使用不同的线型（虚线、点线等），即使以黑白打印，也会出现这种区别。为此，请为不同的算法使用不同的line type 而不是lt 1。