项目宏退出而不删除所有相关任务

Question

我有一个宏，用于删除所有工作量为零的任务，如果它们是 a) 不是关键里程碑（企业定义的字段）或 b) 大于大纲级别 1。

但是，宏退出并且不再继续执行所有满足上述条件的任务。项目计划很长（大约 1840 行），它在 200 行附近停止。宏似乎没有循环所有相关任务，但我不知道为什么。

Sub DeleteMsProjectTask()
Dim proj As Project
Dim t As Task
Dim tsk
Dim mileTsk
Set proj = ActiveProject
For Each t In proj.Tasks
If t.OutlineLevel > 1 And t.Work = 0 Then
   tsk = t.Name
   mileTsk = t.GetField(FieldNameToFieldConstant("Key Milestone?", pjTask))
   If mileTsk = "No" Then
        t.Delete
   Else
   End If
End If
Next t
MsgBox ("Done")
End Sub

Answer 1

更新

更新代码以从子项目中删除任务。

正如 Shai Rado 所逃避的那样，关键是使用索引循环遍历集合，而不是遍历集合。

Sub DeleteMsProjectTask()
    DeleteTasks ActiveProject
    Dim sp As Subproject
    For Each sp In ActiveProject.Subprojects
        DeleteTasks sp.SourceProject
    Next sp
End Sub

Sub DeleteTasks(prj As Project)
    Dim NumTasks As Integer
    NumTasks = prj.Tasks.Count
    Dim idx As Integer
    idx = NumTasks
    Dim t As Task
    Dim mileTsk As String
    Do While idx > 0
        Set t = prj.Tasks(idx)
        If t.OutlineLevel > 1 And t.Work = 0 Then
            mileTsk = t.GetField(FieldNameToFieldConstant("Key Milestone?", pjTask))
            If mileTsk = "No" Then
                t.Delete
                NumTasks = NumTasks - 1
            End If
        End If
        idx = idx - 1
    Loop
End Sub