XML-XSLT-CSV 转换

Question

我正在尝试通过 XSLT 将我的 XML 文档转换为 CSV。到目前为止无法达到预期的效果。

XML 如下：

<projects>
  <project>
    <name>Shockwave</name>
    <language>Ruby</language>
    <owner>Brian May</owner>
    <state>New</state>
    <startDate>31/10/2008 0:00:00</startDate>
  </project>
  <project>
    <name>Other</name>
    <language>Erlang</language>
    <owner>Takashi Miike</owner>
    <state> Canceled </state>
    <startDate>07/11/2008 0:00:00</startDate>
  </project>
  </projects>

XSLT 如下：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" encoding="iso-8859-1"/>

  <xsl:strip-space elements="*" />

  <xsl:template match="/*/child::*">
    <xsl:for-each select="child::*">
      <xsl:if test="position() != last()">
        <xsl:value-of select="normalize-space(.)"/>,
      </xsl:if>
      <xsl:if test="position()  = last()">
        <xsl:value-of select="normalize-space(.)"/><xsl:text>&#xD;</xsl:text>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

输出如下：

虽然要求转换为 CSV，如下所示： 标题是第一行。然后在 startDate 之后换行。

姓名、语言、所有者、州、开始日期

Shockwave, Ruby, Brian May,New,31/10/2008 0:00:00

Other,Erlang,Takashi Miike,Cancelled,07/11/2008 0:00:00

Answer 1

问题出在这句话上

  <xsl:if test="position() != last()">
    <xsl:value-of select="normalize-space(.)"/>,
  </xsl:if>

你正在输出一个逗号，但逗号后面的换行符也会被输出。如果整个文本节点都是空白，XSLT 只会忽略空白。一旦你包含一个非空白字符，它也会输出你的缩进！

所以，你需要把它改成这个……

  <xsl:if test="position() != last()">
    <xsl:value-of select="normalize-space(.)"/><xsl:text>,</xsl:text>
  </xsl:if>

话虽如此，您可以进一步简化您的 XSLT。试试这个

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" encoding="iso-8859-1"/>

  <xsl:strip-space elements="*" />

  <xsl:template match="/*/child::*">
    <xsl:for-each select="child::*">
      <xsl:if test="position() > 1">
        <xsl:text>,</xsl:text>
      </xsl:if>
      <xsl:value-of select="normalize-space(.)"/>
    </xsl:for-each>
    <xsl:text>&#xD;</xsl:text>
  </xsl:template>
</xsl:stylesheet>

编辑：如果您想输出标题行，请将此模板添加到 XSLT

<xsl:template match="/*">
   <xsl:for-each select="*[1]/*">
      <xsl:if test="position() > 1">
        <xsl:text>,</xsl:text>
      </xsl:if>
      <xsl:value-of select="local-name()"/>
   </xsl:for-each>
   <xsl:text>&#xD;</xsl:text>
   <xsl:apply-templates />
</xsl:template>