如果节点具有相同的名称，如何使用 xslt 生成具有相同节点名称下的节点值的数组。输出是 json 形式答案

【问题标题】：if nodes have same name how to generate an array with node values under the same node name using xslt.output is in json form如果节点具有相同的名称，如何使用 xslt 生成具有相同节点名称下的节点值的数组。输出是 json 形式
【发布时间】：2012-06-22 06:38:58
【问题描述】：

我是 xslt 的新手。我必须使用 xslt 将输入作为 xml 生成 json。

这里我的输入xml是这样的

<root> 
<section>   
  <item name="a">  
       <uuid>1</uuid>  
          </item> 
   </section> 
 <section>    
 <item name="b">     
     <uuid>2</uuid>  
   </item> 
     </section> 
   </root>

使用 xslt 我必须得到这样的输出

{ "root" : { "section" : { "item" :[{ "name" : "a", "uuid" : "1"},
                                    { "name" : "b", "uuid" : "2"}] }
}}

我要做的是：

在数组中查找子节点是否同名
如果它们具有相同的名称，则生成一个包含相同节点名称下的节点值的数组

输出必须是json。

【问题讨论】：

对.....你试过什么？
为什么您想要的结果没有section 的数组？这与提供的 XML 文档 1:1 对应。
你试过用谷歌搜索“XSLT to JSON”吗？我认为在这样一个简单的问题中讨论这个任务太琐碎了。

标签： xml json xslt

【解决方案1】：

通常，由于两种语言的差异及其表达能力，XML 文档和 JSON 对象之间不存在 1:1 映射。

这就是说，在你的具体情况下这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vQ">"</xsl:variable>

 <xsl:template match="/*">
{ "root" : { "section" :
 <xsl:apply-templates select="section[1]/*"/>
 }}
 </xsl:template>

 <xsl:template match="item">
  { "item" :
    [<xsl:text/>
      <xsl:apply-templates select="../../*/item" mode="data"/>
     ]
   }
 </xsl:template>

 <xsl:template match="item" mode="data">
   <xsl:if test="position() > 1">, &#xA;&#9;&#9; </xsl:if>
   <xsl:text>{</xsl:text><xsl:apply-templates select="@*|*"/>}<xsl:text/>
 </xsl:template>

 <xsl:template match="item/@* | item/*">
   <xsl:if test="position() > 1">, </xsl:if>
   <xsl:value-of select='concat($vQ, name(), $vQ, " : ", $vQ, ., $vQ)'/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<root>
    <section>
        <item name="a">
            <uuid>1</uuid>
        </item>
    </section>
    <section>
        <item name="b">
            <uuid>2</uuid>
        </item>
    </section>
</root>

产生想要的结果：

{ "root" : { "section" :

  { "item" :
    [{"name" : "a", "uuid" : "1"}, 
         {"name" : "b", "uuid" : "2"}
     ]
   }

 }}

【讨论】：