如何在搜索替换场景中使用 XSLT？

Question

我有一个 XML 文件，在某些位置具有某些值。我希望能够在这些位置替换/添加/删除值。

给出如下：

1. 所有位置仅引用属性节点。
2. 如果位置引用不存在的属性节点，则所有者元素节点必须存在。
3. 新值在编写 XSL 文件时是已知的。

鉴于这些条件，我实现了一个临时解决方案，它接受 XAML 文件中的键值列表，其中键是 XPATH，值是值，并且正是我需要的，只是意识到，我已经有法拉利的时候发明了轮子——XSL变换。

我的问题是这样的。给定一个 XML，XSL 是什么，在该 XML 上应用哪个：

1. 将/a/b/@c 处的值替换为另一个值，例如D。如果某些 /a/b 元素没有 c 属性 - 应该添加它。
2. 删除属性/a/d/@e（如果存在）。否则什么都不做。

谢谢。

Answer 1

XSLT 1.0：

<!-- the identity template copies everything not matched elsewhere -->
<xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*" />
  </xsl:copy>
</xsl:template>

<!-- special handling for /a/b elements -->
<xsl:template match="/a/b">
  <!-- copy the element itself -->
  <xsl:copy>
    <!-- handle all attributes -->
    <xsl:apply-templates select="@*" />
    <!-- create (or overwrite!) an attribute named "c" -->
    <xsl:attribute name="c">
      <xsl:value-of select="'D'" />
    </xsl:attribute>
    <!-- handle all other child nodes -->
    <xsl:apply-templates select="node()" />
  </xsl:copy>
</xsl:template>

<!-- empty template to delete /a/d/@e -->
<xsl:template match="/a/d/@e" />

Answer 2

我建议您在这里对 XSL 的概念化可能会有些错误。听起来好像您是在程序上想象它，即“我如何表达 'Do X to Y'”而不是“从结构 X 到结构 Y 的映射是什么”，这才是 XSL 的真正含义。

你会想要这样的东西：

<xsl:for-each select="//a">
    <xsl:copy>
        <xsl:for-each select="b">
            <xsl:copy>
                <xsl:attribute name="c">
                    <xsl:value-of select="$D"/> 
                </xsl:attribute> 
            </xsl:copy>
        </xsl:for-each
    </xsl:copy>
</xsl:for-each>

（注意，“$D”语法表示变量取消引用，即“插入变量 D 的值”。我猜这就是你想要的，但你可以从任何地方获取 D。）

因此，您实际上不需要告诉 XSL 'add c' 或 'delete e'。你告诉它应该有什么，否则它什么也不做。