如何使用 XSLT 将元素复制到组中的所有元素答案

【问题标题】：How to copy an element to all the elements present in a group using XSLT如何使用 XSLT 将元素复制到组中的所有元素
【发布时间】：2018-12-20 03:34:58
【问题描述】：

我有一个输入 xml，使用下面的 XSL 转换我可以将 deptId 作为子元素添加到“员工”元素，但我想将它作为子元素添加到每个“员工”元素。我是新人到 XSLT 我尝试了以下转换，但没有得到所需的输出

输入 XML：

<?xml version="1.0" encoding="UTF-8"?>
<rootnode>
    <companyName>ABC</companyName>
    <deptId>12</deptId>
    <employee>
       <name>n1</name>
       <empid>e1</empid>
    </employee>
    <employee>
       <name>n2</name>
       <empid>e2</empid>
    </employee>
    <employee>
       <name>n3</name>
       <empid>e3</empid>
    </employee>
</rootnode>

XSL 转换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

 <xsl:template match="/rootnode">
 <xsl:copy>
    <xsl:copy-of select="companyName"/>
     <xsl:copy-of select="deptId"/>

    <employees>
        <xsl:copy-of select="employee"/>
        <xsl:copy-of select="deptId"/>
    </employees>
  </xsl:copy>
 </xsl:template>

</xsl:stylesheet>

输出xml：

<?xml version="1.0" encoding="UTF-8"?>
<rootnode>
    <companyName>ABC</companyName>
    <deptId>D1</deptId>
    <employees>
        <employee>
            <name>n1</name>
            <empid>e1</empid>
        </employee>
        <employee>
            <name>n2</name>
            <empid>e2</empid>
        </employee>
        <employee>
            <name>n3</name>
            <empid>e3</empid>
        </employee>
       <deptId>D1</deptId>
   </employees>
 </rootnode>

所需输出：

<?xml version="1.0" encoding="UTF-8"?>
 <rootnode>
      <companyName>ABC</companyName>
      <deptId>12</deptId>
      <employees>
          <employee>
             <name>n1</name>
             <empid>e1</empid>
             <deptId>12</deptId>
          </employee>
          <employee>
             <name>n2</name>
             <empid>e2</empid>
             <deptId>12</deptId>
          </employee>
          <employee>
             <name>n3</name>
             <empid>e3</empid>
             <deptId>12</deptId>
          </employee>
     </employees>
</rootnode>

我希望将 deptId 复制到 'employees' 元素下的所有 'employee' 元素中，有人可以帮我解决这个问题。

【问题讨论】：

整个文档中是否总是只有一个deptId？
是只有一个deptId

标签： xslt xpath

【解决方案1】：

在您的rootnode 模板匹配中，您可以这样做：

<xsl:template match="rootnode">
    <xsl:copy>
        <xsl:copy-of select="node()[not(self::employee)]"/>
        <employees>
            <xsl:apply-templates select="employee"/>
        </employees>
    </xsl:copy>
</xsl:template>

即复制根节点，复制除employee之外的所有子节点。然后将所有employee节点放入employees中

然后，在您的 employee 模板匹配中，您可以这样做：

<xsl:template match="employee">
    <xsl:copy>
        <xsl:copy-of select="node()"/>
        <xsl:copy-of select="preceding-sibling::deptId"/>
    </xsl:copy>
</xsl:template>

即复制节点及其子节点，并复制前面的兄弟deptId。

整个样式表在下面

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>    

    <xsl:template match="rootnode">
        <xsl:copy>
            <xsl:copy-of select="node()[not(self::employee)]"/>
            <employees>
                <xsl:apply-templates select="employee"/>
            </employees>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="employee">
        <xsl:copy>
            <xsl:copy-of select="node()"/>
            <xsl:copy-of select="preceding-sibling::deptId"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

看到它在行动https://xsltfiddle.liberty-development.net/bFDb2Dq。

【讨论】：