在 xslt 中嵌入标签

Question

我有这个正在工作的 xslt：

<xsl:when test="area_of_expertise">

    <div>
        <xsl:value-of select="area_of_expertise"/>
    </div>
</xsl:when>

但我需要的是：

<xsl:when test="area_of_expertise">

    <div id="<xsl:value-of select="area_of_expertise"/>">
        <xsl:value-of select="area_of_expertise"/>
    </div>
</xsl:when>

但是第二个例子有错误..有人知道为什么吗？

顺便说一句，有没有办法我们可以将节点的名称 area_of_expertise 转换为 areaOfExperiseLabel 并将其作为 id 插入？我真正需要的输出是这样的：

<div id="areaOfExpertiseLabel">
    asasdasdasd
</div>

Answer 1

它出错的原因是它不再是有效的 XML。

做你想做的事：

<xsl:when test="title">

    <div id="{title}">
        <xsl:value-of select="title"/>
    </div>
</xsl:when>

您可以在 {} 标记内放置任何类型的选择器，如果您有复杂的东西，甚至可以引用变量。

<xsl:variable name="some_complex_variable">
    <xsl:value-of select="title"/>
</xsl:variable>

<xsl:when test="title">

    <div id="{$some_complex_variable}">
        <xsl:value-of select="title"/>
    </div>
</xsl:when>

第三种冗长的方法是使用 xsl:attribute: 动态附加属性：

<xsl:when test="title">

    <div>
        <xsl:attribute name="id" select="title"/>
    </div>
</xsl:when>

Answer 2

对于第二部分，请尝试使用此模板：

<xsl:template name="parse">
        <xsl:param name="input"/>
        <xsl:param name="position"/>


        <xsl:if test="$position &lt;= string-length($input)">

            <xsl:choose>
                <xsl:when test="substring($input, $position, 1) = '_'">
                    <xsl:value-of select="translate(substring($input, $position + 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>

                    <xsl:call-template name="parse">
                        <xsl:with-param name="input" select="$input"/>
                        <xsl:with-param name="position" select="$position + 2"/>
                    </xsl:call-template>
                </xsl:when>

                <xsl:otherwise>

                    <xsl:value-of select="substring($input, $position, 1)"/>

                    <xsl:call-template name="parse">
                        <xsl:with-param name="input" select="$input"/>
                        <xsl:with-param name="position" select="$position + 1"/>
                    </xsl:call-template>
                </xsl:otherwise>
            </xsl:choose>

        </xsl:if>


    </xsl:template>

用法：

<xsl:call-template name="parse">
            <xsl:with-param name="input" select="'area_of_expertise'"/>
            <xsl:with-param name="position" select="1"/>
        </xsl:call-template>

Answer 3

对于第二部分，从下划线转换为驼峰式，您可能需要查看String Processing in the XSLT Standard Library。 str:subst() 下划线分割，str:to-camelcase() 适当改变字母大小写，concat() 添加“标签”后缀，你应该设置。

Answer 4

对于第一部分，您可以使用：

<xsl:when test="area_of_expertise">
    <div>
        <xsl:attribute name="id">
            <xsl:value-of select="area_of_expertise"/>
        </xsl:attribute>

        <xsl:value-of select="area_of_expertise"/>
    </div>
</xsl:when>

Answer 5

这可能是一个愚蠢的答案，但您似乎需要这个简单的跟踪：

<xsl:when test="area_of_expertise">
    <div id="areaOfExperiseLabel">
        <xsl:value-of select="area_of_expertise"/>
    </div>
</xsl:when>

否则，如果您需要另一个字符串，为什么您对<xsl:value-of select="area_of_expertise"/> 对@id 感兴趣？