【问题标题】:XSLT regex doesn't match even when in online regex tests match correctly即使在线正则表达式测试正确匹配,XSLT 正则表达式也不匹配
【发布时间】:2019-01-09 10:32:10
【问题描述】:

给定示例路径 C:\example\innerExample\file.txt,我想使用此正则表达式提取带扩展名的文件名,您可以 see it here。

<xsl:analyze-string select="$filePath" regex="$regexPattern" flags="mis">
  <xsl:matching-substring>
    <xsl:value-of select="concat(regex-group(2), regex-group(3))"/>
  </xsl:matching-substring>
</xsl:analyze-string>

这是我的 xslt 代码,有什么我遗漏的吗?

【问题讨论】:

标签: regex xslt xslt-2.0 pcre


【解决方案1】:

无需尝试(我无法重现),我相信您可以简单地使用以下方法提取带有扩展名的文件名:

<xsl:value-of select="tokenize($filepath, '\\')[last()]"/>

演示:http://xsltransform.hikmatu.com/6qVRKvN

【讨论】:

  • 它适用于 windows 路径,但考虑到我可以从外部源提供动态 regexPattern,我该如何应用到我的 $filePath?很抱歉没有给你足够的细节,但我真的是 XSLT 的新手,所以我不知道我在做什么以及如何正确地做。
  • tokenize() 函数的第二个参数实际上是一个正则表达式模式(您可以为标志添加第三个参数)。如需更多信息,请根据要求编辑您的问题。
  • 我如何从这个正则表达式中选择特定的组?
  • @kkot 你不能。但您可以添加其他分隔符。
【解决方案2】:

您没有向我们展示具有正确值的完整但最小的示例,但更正了不转义方括号中的 / 我认为您的模式适用于 XSLT/XPath 2 及更高版本:

输入

<root>
    <data>C:\example\innerExample\file.txt</data>
</root>

在https://xsltfiddle.liberty-development.net/jyRYYhM 用

转换
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:param name="regexPattern" as="xs:string">^(.*)[/|\\](.*)(\..*)</xsl:param>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="data">
      <xsl:copy>
          <xsl:analyze-string select="." regex="{$regexPattern}" flags="mis">
              <xsl:matching-substring>
                <xsl:value-of select="concat(regex-group(2), regex-group(3))"/>
              </xsl:matching-substring>
          </xsl:analyze-string>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

进入

<root>
    <data>file.txt</data>
</root>

(我在那里使用过 XSLT 3,但我认为 XSLT 2 和 3 之间在 xsl:analyze-string 方面没有变化)。

【讨论】:

  • ... 并将regex="$regexPattern" 更改为regex="{$regexPattern}"。
  • @michael.hor257k,没错,不知何故,我在创建示例时自动进行了更改,但忘了提及。 @kkot。 regex 属性需要使用属性值模板语法来使用参数或变量的值。
猜你喜欢
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多