填充某个其他属性时如何使用 XSLT 替换 XML 属性？

Question

我有两个可能的 XML 文件：

<orders>
   <order id="1">
      <code value="001-AAA"/>
      <altCode value="002-BBB"/>
   </order>
</orders>

还有：

<orders>
   <order id="2">
      <code value="001-AAA"/>
      <altCode value=""/>
   </order>
</orders>

我希望将<code>tag 的value 属性替换为<altCode>tag 的value 属性，除非第二个值为空。在那种情况下，我希望 XML te 保持不变。 <altCode>tag 不需要更改。

所以生成的两个 XML 文件应该如下所示：

<orders>
   <order id="1">
      <code value="002-BBB"/>
      <altCode value="002-BBB"/>
   </order>
</orders>

还有：

<orders>
   <order id="2">
      <code value="001-AAA"/>
      <altCode value=""/>
   </order>
</orders>

注意： 我喜欢转换的实际文件要复杂得多。所以我更喜欢复制模板并在使用 when 语句之后更改属性。

非常感谢任何帮助。

Answer 1

我建议你这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="code/@value[string(../../altCode/@value)]">
    <xsl:copy-of select="../../altCode/@value"/>
</xsl:template>

</xsl:stylesheet>