两个 XSL 文件需要一个最终输出文件

Question

我有一个输入文件和两个 XSL 文件 test1.xsl、test2.xsl

1. test1.xsl 文件对输入文件进行转换并生成 test1-output.xml
2. test2.xsl 文件在 test1-output.xml 上转换并生成最终输出

要求：

我正在使用 XSLT 2.0 我想同时运行两个 xslt 文件在输入文件上转换并生成最终输出。 这个需求怎么做，请指教！

输入文件：

<?xml version="1.0" encoding="UTF-8"?>
<k>
    <page>content here</page>
    <page1>content here</page1>
</k>

test1.xsl 文件：

<?xml version="1.0"qqq encoding="UTF-8"?>
<xsl:stylesheet xmqlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output indent="yes" method="xml"/>
    <xsl:template match="@*| node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
<xsl:template match="page">
        <page>
            <kita>
                <xsl:apply-templates/>
            </kita>
        </page>
    </xsl:template>
</xsl:stylesheet>

test1.xsl 的输出

<?xml version="1.0" encoding="UTF-8"?>
<k>
    <page>
      <kita>content here</kita>
   </page>
    <page1>content here</page1>
</k>

test2.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output indent="yes" method="xml"/>
    <xsl:template match="@*| node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="kita">
        <kita>
            <kita1>
                <xsl:apply-templates/>
            </kita1>
        </kita>
    </xsl:template>
</xsl:stylesheet>

这是我从第二个 XSLT 文件中的最终 xml 输出：

<?xml version="1.0" encoding="UTF-8"?>
<k>
    <page>
      <kita>
         <kita1>content here</kita1>
      </kita>
   </page>
    <page1>content here</page1>
</k>

提前致谢

Answer 1

在 XSLT 3 中，您可以编写一个样式表，其中有两个参数调用 fn:transform 两次，例如

<xsl:param name="xslt1" as="document-node()"/>
<xsl:param name="xslt2" as="document-node()"/>

<xsl:template match="/">
  <xsl:sequence
    select="
    transform(map {
      'stylesheet-node' : $xslt1,
      'source-node' : .
    })?output ! transform(map {
      'stylesheet-node' : $xslt2,
      'source-node' : .
    })?output"/>
</xsl:template>

或者如果你想传入文件 URIs

<xsl:param name="xslt1" as="xs:string">test1.xsl</xsl:param>
<xsl:param name="xslt2" as="xs:string">test2.xsl</xsl:param>

<xsl:template match="/">
  <xsl:sequence
    select="
    transform(map {
      'stylesheet-node' : doc($xslt1),
      'source-node' : .
    })?output ! transform(map {
      'stylesheet-node' : doc($xslt2),
      'source-node' : .
    })?output"/>
</xsl:template>