Marklogic 如何从地图创建文档

Question

我需要从地图创建一个特定格式的文档

我有以下代码：

declare function local:buid-map-doc(
  $wijk as xs:string,
  $wm as map:map) as element()
{  
  let $a := for $k in map:keys($wm)
              let $v := map:get($wm,$k)
              return element x {$v}
  return <y>{$a}</y>
};

let $wijk := "101101"
let $wm := map:map()
let $p := map:put($wm, "cat1:::k1",45683)
let $p := map:put($wm, "cat1:::k2",123)
let $p := map:put($wm, "cat2:::k2",123)

return  local:buid-map-doc($wijk,$wm)

给予：

<y>
  <x>123</x>
  <x>123</x>
  <x>45683</x>
</y>

但我想要 map:keys i 元素名称... 如果我这样做：

declare function local:buid-map-doc(
  $wijk as xs:string,
  $wm as map:map) as element()
{  
  let $a := for $k in map:keys($wm)
              let $v := map:get($wm,$k)
              return element {$k} {$v}
  return <y>{$a}</y>
};

let $wijk := "101101"
let $wm := map:map()
let $p := map:put($wm, "cat1:::k1",45683)
let $p := map:put($wm, "cat1:::k2",123)
let $p := map:put($wm, "cat2:::k2",123)

return  local:buid-map-doc($wijk,$wm)

然后我得到如下错误：

[1.0-ml] XDMP-QNAMELEXFORM: let $s := fn:QName("http://www.example.com/example", "k") -- QName 的词法形式无效

添加：

理想情况下，我希望得到这样的输出，可能还有更深的嵌套：

<results>
    <cat1>
        <k1>45683</k1>
        <k2>123</k2>
    </cat1>
    <cat2>
        <k2>123</k2>
    </cat2>
</results>

Answer 1

对于computed element constructors，元素名称的表达式需要在括号中：CompElemConstructor ::= "element" (QName | ("{" Expr "}")) "{" ContentExpr? "}"

declare function local:buid-map-doc(
  $wijk as xs:string,
  $wm as map:map) as element()
{  
  let $a := 
    for $k in map:keys($wm)
    let $v := map:get($wm, $k)
    return element { replace($k, ':::', '-')} { $v }
  return <y>{$a}</y>
};

Answer 2

您的代码的问题是您的映射键不是有效的 QName。所以，实际的错误 id 是正确的，但它报告错误的代码确实很奇怪。我会确保它在 MarkLogic 上得到报告。

解决方案很简单，不要在 map:keys 中使用冒号，或者只使用一个，并且让前面的部分与已知的命名空间前缀匹配。例如。这会起作用：

declare function local:buid-map-doc(
  $wijk as xs:string,
  $wm as map:map) as element()
{  
  let $a := for $k in map:keys($wm)
            let $v := map:get($wm,$k)
            return element {$k} {$v}
  return <y>{$a}</y>
};

let $wijk := "101101"
let $wm := map:map()
let $p := map:put($wm, "cat1_k1",45683)
let $p := map:put($wm, "cat1_k2",123)
let $p := map:put($wm, "cat2_k2",123)

return  local:buid-map-doc($wijk,$wm)

添加：

如果三冒号实际上表示层次结构，最好先将扁平地图转换为嵌套地图。将嵌套映射转换为嵌套 XML 非常简单。这是构建嵌套地图的粗略实现：

declare function local:nest-keys($nested-map, $keys, $value) {
  let $key := $keys[1]
  let $remainder := $keys[position() > 1]
  return
  if ($key) then
    let $_ :=
      if (not(map:contains($nested-map, $key))) then
        map:put($nested-map, $key, map:map())
      else()
    let $key-map :=
      map:get($nested-map, $key)
    return
      if ($remainder) then
        local:nest-keys($key-map, $remainder, $value)
      else
        map:put($nested-map, $key, $value)
  else
    ()
};

let $map := map:map(
<map:map xmlns:map="http://marklogic.com/xdmp/map">
  <map:entry>
    <map:key>cat1:::var1:::seg1</map:key>
    <map:value>waarde1</map:value>
  </map:entry>
  <map:entry>
    <map:key>cat1:::var1:::seg2</map:key>
    <map:value>waarde2</map:value>
  </map:entry>
  <map:entry>
    <map:key>cat1:::var2:::seg1</map:key>
    <map:value>waarde3</map:value>
  </map:entry>
  <map:entry>
    <map:key>cat1:::var2:::seg2</map:key>
    <map:value>waarde4</map:value>
  </map:entry>
  <map:entry>
    <map:key>cat2:::var1:::seg1</map:key>
    <map:value>waarde5</map:value>
  </map:entry>
</map:map>
)
let $nested-map := map:map()
let $_ :=
  for $key in map:keys($map)
  let $keys := tokenize($key, ":::")
  return
    local:nest-keys($nested-map, $keys, map:get($map, $key))
return $nested-map

HTH！