我可以调整此查询以摆脱 fn:distinct-values 吗？

Question

谁能告诉我是否可以通过去掉fn:distinct-values($d2) 表达式来改进这个查询？

xquery version "1.0-ml";
declare namespace zespc = "http://www.cendris.nl/postcode";
declare namespace op = "http://www.nvsp.nl/oplage-mapping";

let $wijk := '665402'
let $d1 := fn:distinct-values(fn:doc('/data/map/oplage-mapping.xml')//op:map[@wijk_id = $wijk]/@ppc6_id)

let $q1 := cts:element-attribute-range-query(
      xs:QName("op:map"), xs:QName("wijk_id"), "=",
      $wijk)

let $d2 := cts:search(//op:map,$q1)/@ppc6_id
let $d3 := fn:distinct-values($d2)

return (fn:count($d1), fn:count($d3))

谢谢，

雨果

Answer 1

我不是 100% 确定您的目标是什么，但这应该会返回相同的结果。您将需要另一个属性范围索引，这次是 op:map/@ppc6_id。

注意排序规则，并在合适的情况下考虑使用数字类型。

xquery version "1.0-ml";
declare namespace zespc="http://www.cendris.nl/postcode";
declare namespace op="http://www.nvsp.nl/oplage-mapping";

let $wijk := '665402' (: Consider using integers instead of strings :)
let $q-wijk := cts:element-attribute-range-query(
  xs:QName("op:map"), xs:QName("wijk_id"),
  '=', $wijk)
let $ref-ppc := cts:element-attribute-reference(
    xs:QName('op:map'), xs:QName('ppc6_id'))
let $values-doc := cts:values(
  $ref-ppc, (),
  cts:and-query(
    (cts:document-query('/data/map/oplage-mapping.xml'),
     $q-wijk)))
let $values-all := cts:values($ref-ppc, (), $q-wijk)
return (count($values-doc), count($values-all))