获取 xsl:variable 中的元素值

Question

请原谅我对 XSLT 的无知，我对它还很陌生。

使用 saxon xslt 2.0：我试图从 xsl:variable 中获取单个元素，在应用 <xsl:copy-of select="$type"> 时看起来像这样：

  <type>
     <label>Book</label>
     <id>book</id>
  </type>

尝试仅访问 id 元素 - 我尝试过：

<xsl:copy-of select="$type/id">
<xsl:copy-of select="$type[2]">
<xsl:value-of select="$type/id">
<xsl:value-of select="$type[2]">

也试过这个和一些变种

<xsl:value-of select="$type[name()='id']"/>

并尝试更改数据类型

<xsl:variable name="type" as="element"> 

XSLT 2.0 node-set() 操作似乎不适用。

我寻求有关如何正确访问 xsl:variable 元素的详细说明，并且很高兴发现我使用这一切都错了，有更好的方法。感谢您的见解和努力。

@martin-honnen 添加时：

<xsl:variable name="test1">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

<TEST1><xsl:copy-of select="$test1/type/id"/></TEST1>

<xsl:variable name="test2" as="element()">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

<TEST2><xsl:copy-of select="$test2/id"/></TEST2>

我得到了结果：

   <TEST1/>
   <TEST2/>

Answer 1

如果你有

<xsl:variable name="type">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

那么你需要例如<xsl:copy-of select="$type/type/id"/> 复制id 元素，因为type 变量绑定到包含type 元素节点和id 子元素节点的临时文档节点。

或者使用

<xsl:variable name="type" as="element()">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

然后<xsl:copy-of select="$type/id"/> 有效，因为现在变量绑定到type 元素节点。

以下是我的建议的完整示例：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

<xsl:output indent="yes"/>

<xsl:template match="/">

<xsl:variable name="test1">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

<TEST1><xsl:copy-of select="$test1/type/id"/></TEST1>

<xsl:variable name="test2" as="element()">
  <type>
     <label>Book</label>
     <id>book</id>
  </type>
</xsl:variable>

<TEST2><xsl:copy-of select="$test2/id"/></TEST2>

</xsl:template>

</xsl:stylesheet>

输出是

<TEST1>
   <id>book</id>
</TEST1>
<TEST2>
   <id>book</id>
</TEST2>

Answer 2

要访问元素值，只需正确指定 XPath，即 type/id

<xsl:value-of select="type/id" />