XSL：通过递归创建值的同时添加兄弟节点

Question

输入：

<root>
  <name>a,b,c,d,e,f,g,h,i,j,k,</name>
  <value>1,,3,,5,,7,,,,11,<value>
</root>

预期输出

<root>
  <out>a:1|c:3|e:5|g:7|k:11</out>
  <e>5</e>
  <j/>
</root>

我能够通过递归得到预期的'out。 但是我需要分别打印两个值，例如“e”和“j”。 循环时，如果名称是 'e' 或 'j'，则应创建这些元素。我无法做到。

递归代码

<xsl:template match="//root">
      <xsl:param name="columnName" select="a,b,c,d,e,f,g,h,i,j,k"></xsl:param>

        <root>
           <out>
            <xsl:call-template name="merge">
                <xsl:with-param name="name" select="normalize-space(name)" />
                 <xsl:with-param name="value" select="normalize-space(value)" />
            </xsl:call-template>                    
          </out>
       </root>
     </xsl:template>

    <xsl:template name="merge">
        <xsl:param name="name" />
        <xsl:param name="value" />
        <xsl:param name="separator" select="','" />  
           <xsl:variable name="currentValue"  select="substring-before($value, $separator)"/>
            <xsl:if test="$currentValue!=''">
                <xsl:value-of select="substring-before($name, $separator)" /><xsl:text>:</xsl:text>
                <xsl:value-of select="$currentValue" /><xsl:text>|</xsl:text>
            </xsl:if>
            <xsl:call-template name="merge">
                <xsl:with-param name="value" select="normalize-space(substring-after($value, $separator))" />
                 <xsl:with-param name="name" select="normalize-space(substring-after($name, $separator))" />
            </xsl:call-template>
    </xsl:template> 

如何在循环中添加两个元素以获取“退出”。

Answer 1

另一种方法是将“合并”模板更改为<a>1</a> 形式的输出元素，您可以将其存储在变量中并进行操作以获得所需的输出。

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="//root">
    <xsl:variable name="nodes">
      <xsl:call-template name="merge">
        <xsl:with-param name="name" select="normalize-space(name)" />
        <xsl:with-param name="value" select="normalize-space(value)" />
      </xsl:call-template>              
    </xsl:variable>
    <root>
      <out>
        <xsl:value-of select="$nodes/*[normalize-space()]/concat(name(), ':', .)" separator="|" />
        <!-- Alternate approach if above does not work
        <xsl:for-each select="$nodes/*[normalize-space()]">
          <xsl:if test="position() > 1">|</xsl:if>
          <xsl:value-of select="concat(name(), ':', .)" />
        </xsl:for-each>
        -->
      </out>
      <xsl:copy-of select="$nodes/e" />
      <xsl:copy-of select="$nodes/j" />
    </root>
  </xsl:template>

  <xsl:template name="merge">
    <xsl:param name="name" />
    <xsl:param name="value" />
    <xsl:param name="separator" select="','" />  
    <xsl:variable name="currentName" select="substring-before($name, $separator)"/>
    <xsl:if test="$currentName!=''">
      <xsl:element name="{$currentName}">
        <xsl:value-of select="substring-before($value, $separator)" />  
      </xsl:element>
      <xsl:call-template name="merge">
        <xsl:with-param name="value" select="normalize-space(substring-after($value, $separator))" />
        <xsl:with-param name="name" select="normalize-space(substring-after($name, $separator))" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template> 
</xsl:stylesheet>

在http://xsltfiddle.liberty-development.net/6qVRKwD/1查看它的实际应用

Answer 2

当您来自程序性思维时，很自然地会想到“当我循环遍历这些值时，我会计算出稍后需要的其他东西作为副作用”。通常对于函数式编程，最好换一种方式思考。在输出中独立计算你需要的每一件事，不要试图在一次输入中计算几件事。

但是，您可以做的是将变量预先计算为输入数据的函数，如果它们将不止一次有用的话。所以在 XSLT 2.0 中你可以这样做

<xsl:variable name="names" select="tokenize(name, ',')"/>
<xsl:variable name="values" select="tokenize(value, ',')"/>

然后你可以写一个函数

<xsl:function name="f:value" as="xs:string">
  <xsl:param name="key" as="xs:string"/>
  <xsl:sequence select="$values[index-of($names, $key)]"/>
</xsl:function>

然后你可以这样做，例如：

<e><xsl:value-of select="f:value('e')"/></e>
<j><xsl:value-of select="f:value('j')"/></j>

如果您可以使用 XSLT 3.0，那么解决所有这些问题的自然方法就是使用映射。像这样：

<xsl:variable name="names" select="tokenize(name, ',')"/>
<xsl:variable name="map" as="map(*)"
  select="map:merge(
           for-each-pair($names, 
                         tokenize(value, ','),
                         function($k, $v) {map{$k, $v}}))"/>
</xsl:variable>
<out>
  <xsl:value-of select="$names ! (. || ':' || $map(.))" separator="|"/>
</out>
<e>{$map?e}</e>
<j>{$map?j}</j>

Answer 3

如果您至少支持 XSLT 2，那么您可以使用 tokenize 并将您的两个值序列转换为一些 XML，然后您可以进一步处理：

<xsl:transform 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all" 
  version="2.0">

  <xsl:output method="xml" indent="yes" />

  <xsl:template match="root">
      <xsl:copy>
          <xsl:variable name="pairs">
              <xsl:variable name="values" select="tokenize(value, ',')"/>
              <xsl:for-each select="tokenize(name, ',')[. castable as xs:QName]">
                <xsl:element name="{.}">
                  <xsl:variable name="pos" select="position()"/>
                  <xsl:value-of select="$values[$pos]"/>
                </xsl:element>
              </xsl:for-each>
          </xsl:variable>
          <out>
              <xsl:value-of select="$pairs/(* except (e, j))[normalize-space()]/concat(name(), ':', .)" separator="|"/>
          </out>
          <xsl:copy-of select="$pairs/(e, j)"/>
      </xsl:copy>
  </xsl:template>

</xsl:transform>

http://xsltransform.hikmatu.com/gWcDMez

使用 XSLT 3，您甚至可以将从 tokenize 返回的字符串序列推送到模板以构造中间 XML（尽管我不得不承认我喜欢使用 Michael Kay 已经发布的地图的建议，而不仅仅是这个用途XML):

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    expand-text="yes"
    version="3.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match=".[. instance of xs:string]">
      <xsl:param name="values"/>
      <xsl:element name="{.}">{ let $pos := position() return $values[$pos] }</xsl:element>
  </xsl:template>

  <xsl:template match="root">
      <xsl:copy>
          <xsl:variable name="pairs">
              <xsl:apply-templates select="tokenize(name, ',')[. castable as xs:QName]">
                  <xsl:with-param name="values" select="tokenize(value, ',')"/>
              </xsl:apply-templates>
          </xsl:variable>
          <out>
              <xsl:value-of select="$pairs/(* except (e, j))[normalize-space()]!(name() || ':' || .)" separator="|"/>
          </out>
          <xsl:copy-of select="$pairs/(e, j)"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/bdxtqz/1