XSLT：如何找到节点的唯一子节点的计数？

Question

我的 XML 如下所示：

<foo>
    <bar name="a">
        <baz name="xyz">
            <time>2</time>
            <date>3</date>
        </baz>
    </bar>
    <bar name="b">
        <baz name="xyz">
            <time>2</time>
            <date>3</date>
        </baz>
    </bar>
    <bar name="c">
        <baz name="xyz">
            <time>2</time>
            <date>3</date>
        </baz>
    </bar>
</foo>

我正在编写一个需要像这样运行的 XSL：如果所有 baz 子代都相同，则 doSomething 否则 doSomethingElse。我当前的节点是foo。

我是 XSLT 的新手，我知道 XSL 中的条件。到目前为止，它看起来像这样：

<xsl:template match="foo">   
<xsl:choose>
    <xsl:when test="[My condition]"> 
        doSomething()
    </xsl:when>
    <xsl:otherwise>
        doSomethingElse()
    </xsl:otherwise>
</xsl:choose>
</xsl:template>

在当前示例中，它应该是doSomething()，因为所有baz 元素都是相同的。

如果我找出唯一baz 元素的数量，我可以测试它是否等于一。如果是，那我就doSomething() 否则doSomethingElse()

我应该如何实现这个？ MyCondition 应该是什么？

PS：我的 XSL 版本是 1.0

Answer 1

如果所有 baz 子代都相同，则 doSomething 否则 doSomethingElse。我当前的节点是foo。

这很令人困惑，因为：

• baz 不是foo 的孩子；
• 您的标题显示“找出唯一孩子的数量” - 但不是 必须找到它才能知道它们是否相同。

尝试类似：

<xsl:template match="foo">
    <xsl:variable name="first-baz" select="(bar/baz)[1]" />
    <xsl:choose>
        <xsl:when test="bar/baz[date!=$first-baz/date or time!=$first-baz/time]">
            <!-- THEY ARE NOT ALL SAME -->
        </xsl:when>
        <xsl:otherwise>
            <!-- THEY ARE ALL SAME -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

请注意，这假定每个baz 都有一个date 和一个time。否则你需要测试not(date=$first-baz/date)等。

另请参阅： http://www.jenitennison.com/xslt/grouping/muenchian.html

---

补充：

现在，假设所有 bar/baz 元素具有相同的标签（不是 必须是date 和time，但是说a、b 和c)，会是什么 该案例的测试属性？

这使它变得更加复杂。你仍然可以构造一个密钥：

<xsl:key name="first-baz" match="foo/bar[1]/baz[1]/*" use="name()" />

然后进行测试：

<xsl:when test="bar/baz/*[. != key('first-baz', name())]">

如果存在baz 的任何子节点，其字符串值不同于作为第一个baz 子节点的同名节点，则返回true。

请注意，此处定义的键是文档范围的。如果要将测试限制在当前的 foo 祖先，则必须在键中包含其 id。

Answer 2

如果您想以通用方式执行此操作，那么您实际上是在将 XSLT 1.0 的功能扩展到其设计限制之外。但这是可以完成的。

编写一个名为 deep-equal 的命名模板，它接受两个元素作为其参数，当且仅当它们不相等时才返回一个包含字符“F”的字符串（出于您的目的）。

它可能看起来像这样：

<xsl:template name="deep-equal">
  <xsl:param name="a"/>
  <xsl:param name="b"/>
  <xsl:choose>
    <xsl:when test="local-name(a) != local-name(b)">F</xsl:when>
    <xsl:when test="namespace-uri(a) != namespace-uri(b)">F</xsl:when>
    <xsl:when test="normalize-space(a) != normalize-space(b)">F</xsl:when>
    <xsl:when test="count(a/*) != count(b/*)">F</xsl:when>
    <xsl:otherwise>
      <xsl:variable name="diffs">
        <xsl:for-each select="*">
          <xsl:variable name="position" select="position()"/>
          <xsl:call-template name="deep-equal">
            <xsl:with-param name="a" select="."/>
            <xsl:with-param name="b" select="$b/*[$position]"/>
          </xsl:call-template>
        </xsl:for-each>
      </xsl:variable>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

将此应用于所有相关的元素对：

    <xsl:variable name="comparison">
      <xsl:for-each select="baz[position() &gt;= 2]">
       <xsl:call-template name="deep-equal">
         <xsl:with-param name="a" select="../baz[1]"/>
         <xsl:with-param name="b" select="."/>
       </xsl:call-template>
      </xsl:for-each>
    </xsl:variable>

测试结果是否包含“F”：

<xsl:if test="contains($comparison, 'F')">...</xsl:if>