在使用 XPath 的复杂 XML 元素中，在空白文本节点中选择子文本节点

Question

我一直在为此绞尽脑汁，但似乎无法正确解决，而且我在 Google 上没有找到正确的关键字..

我最近开始使用 XSLT 和 XPath 来为我的一个项目创建自然语言词汇表的 XML 描述。

问题是我选择对某些单词使用“混合内容”复杂元素，并且在某些情况下只想获取文本节点。

这是 XML 文档的一部分：

...
<entry category="substantiv">
  <word lang="sv">semester</word>
  <word lang="de">
    <article>der</article>Urlaub
    <plural>Urlaube</plural>
  </word>
</entry>
...

我的文档中有很多入口元素，在这种情况下，我想使用 /entry/word[@lang='de']/text() 获取“Urlaub”，因为我的换行符不起作用。我发现实际上有三个文本节点.. .../text()[2] 当然可以工作.. 但是，我事先不知道哪里会有换行符，或者有多少。如果 xml 格式如下，我的第一个版本的路径将起作用，但不是第二个：

...
<word lang="de"><article>der</article>Urlaub
  <plural>Urlaube</plural>
</word>
...

我想我想做的是选择 word[@lang='de'] 的所有直接文本节点，然后使用normalize-space() 删除不必要的空格。但是，我如何使用 XPath 做到这一点？或者，还有更好的方法？这似乎很容易，但我无法弄清楚。顺便说一下，我正在尝试在 XSLT 文档中执行此操作。

normalize-space(/entry/word[@lang='de']/text()[*]) 是我尝试过的事情之一，但这似乎做了别的事情。

/感谢任何帮助。

更新：

根据要求，这是 XSLT 的一部分：

...
<xsl:choose>
    <xsl:when test="@category='substantiv'">
        <em><xsl:value-of select="word[@lang='de']/article" /></em>
        <xsl:value-of select="normalize-space(word[@lang='de']/text()[2])" />
        <em>pl. <xsl:value-of select="word[@lang='de']/plural" /></em>
    </xsl:when>
...

此代码适用于第一个版本的格式化。澄清一下，我想要做的是在复杂元素<word lang="de"> 中获取文本节点的值，尽管它可能是用换行符和空格格式化的。我将如何处理该值取决于上下文，但现在我只是将它放在一个 xhtml 文档中。

更新 2： 我现在使用<xsl:strip-space elements="*"/>，它消除了文本节点为空的问题。我也在使用：

...
<xsl:choose>
  <xsl:when test="@category='substantiv'">
    <em><xsl:value-of select="word[@lang='de']/article" /></em>
    <xsl:text> </xsl:text>
    <xsl:value-of select="normalize-space(word[@lang='de']/text())" />
    <xsl:text>, </xsl:text>
    <em>pl. <xsl:value-of select="word[@lang='de']/plural" /></em>
  </xsl:when>
...

仍然需要规范化，因为在 XML 中的“Urlaub”之后仍然添加了一个空格。

当我需要访问我使用的 XSLT 文档之外的文本节点“Urlaub”时：
<xsl:value-of select="normalize-space(word[@lang='de']/text()[normalize-space() != ''])" />

感谢所有帮助的人！

更新 3： 试图改进标题

Answer 1

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
  <xsl:value-of select="/*/entry/word[@lang='de']/text()[1]"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时（包装在 dict 顶部元素中）：

<dict>
    <entry category="substantiv">
        <word lang="sv">semester</word>
        <word lang="de">
            <article>der</article>Urlaub
            <plural>Urlaube</plural>
        </word>
    </entry>
</dict>

准确地产生想要的结果：

Urlaub

注意：使用<xsl:strip-space> 指令从源 XML 文档中消除所有仅包含空格的文本节点。

因此，不需要额外的处理（normalize-space() 等）。

Answer 2

试试：

/entry/word[@lang='de']/child::text()[normalize-space(.) != '']

意思是，抓取所有子文本节点，但不抓取那些标准化为空字符串的子节点。

-奥辛

Answer 3

我认为这是您想要的框架，减去任何 normalize-space() 以使事物看起来完全符合您的要求。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="/">
    <xsl:apply-templates select=".//word"/>
  </xsl:template>
  <xsl:template match="word">
    <xsl:apply-templates select=".//text()"/>
  </xsl:template>
  <xsl:template match="text()"><xsl:value-of select="."/><xsl:text> </xsl:text></xsl:template>  
</xsl:stylesheet>

键是.//text()，它返回上下文node()下方任何嵌套级别的所有子文本节点的串联。

Answer 4

现在我看到了你的代码，我推荐这个：

<xsl:choose>
  <xsl:when test="@category='substantiv'">
    <em><xsl:value-of select="word[@lang='de']/article" /></em>^
    <!-- select the first non-empty text node and normalize it -->
    <xsl:value-of select="normalize-space(word[@lang='de']/text()[normalize-space() != ''][1])" />
    <em>pl. <xsl:value-of select="word[@lang='de']/plural" /></em>
  </xsl:when>

---

答案的原版

让您开始：

<entry category="substantiv">
  <word lang="sv">semester</word>
  <word lang="de">
    <article>der</article>Urlaub
    <plural>Urlaube</plural>
  </word>
</entry>

通过此 XSLT 1.0 时：

<!-- identity template copies everything 1:1, unless other templates apply -->
<xsl:template match="*|@*">
  <xsl:copy>
    <xsl:apply-templates select="*|@*" />
  </xsl:copy>
</xsl:template>

<!-- empty template: ignore every white-space-only text-node child of <word> -->
<xsl:template match="word/text()[normalize-space() = '']" />

会产生这个：

<entry category="substantiv">
  <word lang="sv">semester</word>
  <word lang="de"><article>der</article>Urlaub<plural>Urlaube</plural></word>
</entry>

这个答案是一个猜测，可能不是你所追求的。无论如何，您的问题都需要澄清。你认为你想要的和你实际上想要的并不总是一样。