在 XSLT 中创建地图答案

【问题标题】：Creating a Map in XSLT在 XSLT 中创建地图
【发布时间】：2012-08-27 17:32:44
【问题描述】：

<xsl:variable name="map">
   <map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </map>
</xsl:variable>

<xsl:for-each select "$map/map/item">
   <xsl:if test="./@key = $input">
      <!-- cool user is asking for something know .. do something fancy -->
   </xsl:if>
<xsl:for-each>

我想在我的 XSLT 中声明一个类似映射的结构，然后想要访问它。显然，我不想使用额外的名称空间，所以使用 exsl:node-set 不是我现在正在寻找的解决方案。

我正在使用 XSLT 1.0 Saxon。

有没有更好的方法来做我想做的事情？

谢谢卡勒菲尔

下面提到的所有答案都是正确有效的。我们最终决定使用“exsl:node-set”

感谢您的建议..

【问题讨论】：

为什么不想使用额外的命名空间？您的意思是不想使用扩展程序？
坦率地说 - 我还没有研究过这是否会影响性能以及是否允许我在我正在修改的 xslt 中添加新的命名空间。
命名空间不一定会损害性能，也不一定意味着它会加载任何额外的代码/模块。正如@LarsH 建议的那样，您可以使用命名空间来简单地唯一限定您的 XML，并将其嵌入到您的 XSLT 中或从外部文件加载。
为了他们自己的利益而禁止你使用额外的命名空间是愚蠢的。这就像禁止 cmets 或新变量一样。但是，如果有人想避免使用扩展功能的可移植性问题，我可以理解。在任何情况下，都不需要使用node-set()，正如我和 Mads 的回答所示。

标签： xml xslt xslt-1.0 saxon

【解决方案1】：

如果您使用的是 Saxon，那么很难理解为什么您仍在使用 XSLT 1.0。这种事情（以及许多其他事情）在 XSLT 2.0 中要容易得多 - 现在是您前进的时候了。

【讨论】：

@OP - XSLT 2.0 与 1.0 非常向后兼容，因此没有理由担心破坏现有样式表。

【解决方案2】：

您可以直接在 XSLT 中包含额外的 XML 信息，例如 <map>。该 XML 数据需要绑定到命名空间（XSLT 命名空间除外），但它可以是任何命名空间。

您可以使用带有空字符串的document() 函数访问XSLT 中的数据，这将加载XSLT 文档。

顺便说一句，您可以通过在 xsl:for-each 选择的 XPath 上使用谓词过滤器来消除对 <xsl:if> 的需求。

例如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"
    xmlns:my="http://stackoverflow.com/questions/12146687/creating-a-map-in-xlst">

    <xsl:param name="input" />

    <my:map >
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

    <xsl:template match="/">
        <xsl:for-each select="document('')/*/my:map/item[@key=$input]">
                <!-- cool user is asking for something know .. do something fancy -->
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

【讨论】：

好答案 - 我没想过使用document('')。
如果这个 XSLT 是从另一个 XSLT 引用的 .. 同样有 100 个 XSLT 被引用 .. 加载当前执行的 xslt 或所有 XSLT 的 document('') ?性能怎么样？

【解决方案3】：

如果您不想使用node-set() 扩展功能，可以将<map> 数据放在单独的XML 文件中，例如map.xml。然后使用document('map.xml') 从您的样式表中访问该文件。然后，您可以使用 XPath 表达式访问地图的内容，如上所示。

【讨论】：

【解决方案4】：

你得到了三个非常好的答案。

这是另一个，它演示了如何使用键来访问查找表（在实际情况下，它会驻留在单独的 XML 文档中）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

 <xsl:key name="kLookup" match="item/@value" use="../@key"/>

 <xsl:template match="/">
     <xsl:for-each select="document('')">
       <xsl:value-of select="key('kLookup', $pInput)"/>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于任何 XML 文档（未使用）时，会产生所需的正确结果：

(878)876678

在 XSLT 2.0 中，xsl:for-each 不需要，因为 key() 函数接受第三个参数来指定要索引的文档：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

 <xsl:key name="kLookup" match="item/@value" use="../@key"/>

 <xsl:template match="/">
       <xsl:value-of select="key('kLookup', $pInput, document(''))"/>
 </xsl:template>
</xsl:stylesheet>

【讨论】：