重写对象属性 - 使用 Moose 的最佳方法？

Question

让我们看看SO问题进入机器人预测，显然是根据问题标题发布的，是否会成真：

您提出的问题看起来很主观，很可能已经结束。

使用 Perl/Moose，我想弥补商家文章的两种表示方式之间的不匹配。让一篇文章有​​name、quantity和price。第一种表示方式是将数量设置为任何数值，包括十进制值，因此您可以拥有 3.5 米长的绳索或电缆。我必须与之交互的第二个是，唉，不灵活，并且要求quantity 是一个整数。因此，我必须重写我的对象以将 quantity 设置为 1，并将实际数量包含在 name 中。 （是的，这是一个 hack，但我想让示例保持简单。）

所以这里的故事是一个属性的值会影响其他属性的值。

这是工作代码：

#!perl
package Article;
use Moose;

has name        => is => 'rw', isa => 'Str', required => 1;
has quantity    => is => 'rw', isa => 'Num', required => 1;
has price       => is => 'rw', isa => 'Num', required => 1;

around BUILDARGS => sub {
    my $orig = shift;
    my $class = shift;
    my %args = @_ == 1 ? %{$_[0]} : @_;
    my $q = $args{quantity};
    if ( $q != int $q ) {
        $args{name}    .= " ($q)";
        $args{price}   *= $q;
        $args{quantity} = 1;
    }
    return $class->$orig( %args );
};

sub itemprice { $_[0]->quantity * $_[0]->price }

sub as_string {
    return sprintf '%2u * %-40s (%7.2f) %8.2f', map $_[0]->$_,
    qw/quantity name price itemprice/;
}

package main;
use Test::More;

my $table = Article->new({ name => 'Table', quantity => 1, price => 199 });
is $table->itemprice, 199, $table->as_string;

my $chairs = Article->new( name => 'Chair', quantity => 4, price => 45.50 );
is $chairs->itemprice, 182, $chairs->as_string;

my $rope = Article->new( name => 'Rope', quantity => 3.5, price => 2.80 );
is $rope->itemprice, 9.80, $rope->as_string;
is $rope->quantity, 1, 'quantity set to 1';
is $rope->name, 'Rope (3.5)', 'name includes original quantity';

done_testing;

不过，我想知道在 Moose 中是否有更好的习惯用法。但也许我的问题都是主观的，应该迅速结束。 :-)

根据 perigrin 的回答更新

我已经修改了 perigrin 的代码示例（小错误和 5.10 语法）并将我的测试标记到它的末尾：

package Article::Interface;
use Moose::Role;
requires qw(name quantity price);

sub itemprice { $_[0]->quantity * $_[0]->price }

sub as_string {
        return sprintf '%2u * %-40s (%7.2f) %8.2f', map $_[0]->$_,
        qw/quantity name price itemprice/;
}


package Article::Types;
use Moose::Util::TypeConstraints;
class_type 'Article::Internal';
class_type 'Article::External';
coerce 'Article::External' =>
  from 'Article::Internal' => via
{
        Article::External->new(
                name        => sprintf( '%s (%s)', $_->name, $_->quantity ),
                quantity    => 1,
                price       => $_->quantity * $_->price
        );
};


package Article::Internal;
use Moose;
use Moose::Util::TypeConstraints;
has name        => isa => 'Str', is => 'rw', required => 1;
has quantity    => isa => 'Num', is => 'rw', required => 1;
has price       => isa => 'Num', is => 'rw', required => 1;

my $constraint = find_type_constraint('Article::External');

=useless for this case
# Moose::Manual::Construction - "You should never call $self->SUPER::BUILD,
# nor"should you ever apply a method modifier to BUILD."
sub BUILD {
        my $self = shift;
        my $q = $self->quantity;
    # BUILD does not return the object to the caller,
    # so it CANNOT BE USED to trigger the coercion.
        return $q == int $q ? $self : $constraint->coerce( $self );
}
=cut

with qw(Article::Interface); # need to put this at the end


package Article::External;
use Moose;
has name        => isa => 'Str', is => 'ro', required => 1;
has quantity    => isa => 'Int', is => 'ro', required => 1;
has price       => isa => 'Num', is => 'ro', required => 1;

sub itemprice { $_[0]->price } # override

with qw(Article::Interface); # need to put this at the end


package main;
use Test::More;

my $table = Article::Internal->new(
        { name => 'Table', quantity => 1, price => 199 });
is $table->itemprice, 199, $table->as_string;
is $table->quantity, 1;
is $table->name, 'Table';

my $chairs = Article::Internal->new(
        name => 'Chair', quantity => 4, price => 45.50 );
is $chairs->itemprice, 182, $chairs->as_string;
is $chairs->quantity, 4;
is $chairs->name, 'Chair';

my $rope = Article::Internal->new(
        name => 'Rope', quantity => 3.5, price => 2.80 );
# I can trigger the conversion manually.
$rope = $constraint->coerce( $rope );
# I'd like the conversion to be automatic, though.
# But I cannot use BUILD for doing that. - XXX
# Looks like I'd have to add a factory method that inspects the
# parameters and does the conversion if needed, and it is always
# needed when the `quantity` isn't an integer.

isa_ok $rope, 'Article::External';
is $rope->itemprice, 9.80, $rope->as_string;
is $rope->quantity, 1, 'quantity set to 1';
is $rope->name, 'Rope (3.5)', 'name includes original quantity';

done_testing;

我同意它提供了更好的关注点分离。另一方面，我不相信这对我的目的来说是一个更好的解决方案，因为它增加了复杂性并且不提供自动转换（为此我必须添加更多代码）。

Answer 1

根据您在 cmets 中提供的信息，您实际上是在对两个不同但相关的事物进行建模。你已经遇到了试图将这两个东西作为一个类来保持的丑陋。你最终没有正确地分离你的关注点并且有丑陋的调度逻辑。

您需要有两个具有通用 API 的类（角色将强制执行此操作）和一组强制转换，以便在两者之间轻松转换。

首先，API 非常简单。

 package Article::Interface {
        use Moose::Role;

        requires qw(name quantity price);

        sub itemprice { $_[0]->quantity * $_[0]->price }

        sub as_string {
            return sprintf '%2u * %-40s (%7.2f) %8.2f', map $_[0]->$_,
            qw/quantity name price itemprice/;
        }
 }

然后你有一个类来代表你的内部文章，这也是很简单的。

 package Article::Internal {
      use Moose;

      has name => ( isa 'Str', is => 'rw', required => 1);
      has [qw(quantity price)] => ( isa => 'Num', is => 'rw', required => 1); 

      # because of timing issues we need to put this at the end
      with qw(Article::Interface);
 }

最后你有一个类来代表你的外部文章。在这一点中，您必须重写接口中的一些方法以处理您的属性将被专门化的事实[^1]。

 package Article::External {
      use Moose;

      has name => ( isa 'Str', is => 'ro', required => 1);
      has quantity => ( isa => 'Int', is => 'ro', required => 1); 
      has price => (isa => 'Num', is => 'ro', required => 1);

      sub itemprice { $_[0]->price }

      # because of timing issues we need to put this at the end
      with qw(Article::Interface);
 }

最后，您定义一个简单的强制例程来在两者之间进行转换。

package Article::Types {
    use Moose::Util::TypeConstraints;
    class_type 'Article::Internal';
    class_type 'Article::External';

    coerce 'Article::Exteral' => from 'Article::Internal' => via {          
         Article::External->new(
            name => $_->name,
            quantity => int $_->quantity,
            price => $_->quantity * $_->price
         );
    }
}

您可以通过以下方式手动触发此强制：

find_type_constraint('Article::External')->coerce($internal_article);

另外 MooseX::Types 可用于最后一部分以提供更清洁的糖，但我在这里选择坚持使用纯 Moose。

[^1]：您可能已经注意到我已将外部文章中的属性设置为只读。从您所说的来看，这些对象应该是“仅消费”，但如果您需要属性是可写的，您需要定义一个强制数量来处理确保只存储整数.我将把它作为练习留给读者。