我应该如何在初始化后定义 Moose 对象子例程？

Question

Moose 对象子程序在初始化后应该如何定义？

我正在使用 Moose 编写一个对象模块，我计划序列化 (nstore) 创建的对象。

检查以下（简化的！）示例：

package MyObj 0.001;

use Moose;
use namespace::autoclean;

has 'size' => (
 is       => 'ro',
 isa      => 'Int',
 required => 1,
);

sub some_sub {
 my ($self, @more) = @_;
 if ($self->size() < 100) # do something;
 elsif (($self->size() < 500)) # do something else;
 elsif (($self->size() < 7500)) # do something else;
 # ...
}

1;

some_sub 的行为因size 而不同。由于size 是只读的，所以在对象初始化后它保持不变。

所以，假设我调用some_sub 无数次，很遗憾我每次都必须通过所有ifs。

我最好在对象初始化后执行一次，然后将some_sub 设置为一个更简单的函数，根本没有ifs。

但是……我该怎么做呢？

更新

也许我应该添加一个 subref 类型的lazy 属性，它将保存对所选子例程的引用。然后some_sub 将简单地调用$self->chosen_sub->(@_)。你怎么看？

Answer 1

has calculation_method => (is => 'ro', lazy_build => 1, init_arg => undef);

sub _build_calculation_method {
    my $self = shift;
    return '_calculate_small'  if $self->size < 100;
    return '_calculate_medium' if $self->size < 500;
    return '_calculate_large'  if $self->size < 7500;
    return '_calculate_enormous';
}

sub _calculate_small  { ... }
sub _calculate_medium { ... }
# etc.

sub calculate {
    my $self = shift;
    my $method = $self->calculation_method;
    return $self->$method(@_);
}

另外，calculation_method 现在也可以序列化了。

Answer 2

MooseX::SingletonMethod 可能是另一种情况！ （对不起，我正在以相反的顺序阅读您的问题！）。

例如：

use 5.012;
use warnings;

package MyObj 0.001;
use MooseX::SingletonMethod;
use namespace::autoclean;

has 'size' => (
    is       => 'ro',
    isa      => 'Int',
    required => 1,
);

sub _which_sub {
    my ($self) = @_;

    if    ($self->size < 100)  { return sub{ 'A' } }
    elsif ($self->size < 500)  { return sub{ 'B' } }
    elsif ($self->size < 7500) { return sub{ 'C' } } 
    return sub { 'D' };
}


package main;

my $obj = MyObj->new( size => 200 );

$obj->add_singleton_method( some_sub => $obj->_which_sub );

say $obj->some_sub;  # => B

并且应该可以从您的类中添加这个单一的方法创建。请查看此博客文章以获得一些指导：Moose Singleton Method: Now without roles!。还有一大堆帖子here

Answer 3

关于您的更新：

use 5.012;
use warnings;

package MyObj;
use Moose;
use namespace::autoclean;

has 'size' => (
    is       => 'ro',
    isa      => 'Int',
    required => 1,
);

has 'chosen_sub' => (
   is       => 'ro',
   isa      => 'CodeRef',
   lazy     => 1,
   builder  => '_build_chosen_sub',
   init_arg => undef, # unless want option of providing anon sub at construction?
);

sub _build_chosen_sub {
    my ($self) = @_;

    if    ($self->size < 100)  { return sub{ 'A' } }
    elsif ($self->size < 500)  { return sub{ 'B' } }
    elsif ($self->size < 7500) { return sub{ 'C' } } 
    return sub { 'D' };
}

package main;
my $obj = MyObj->new( size => 200 );
say $obj->chosen_sub->();  # => B