如果未选择任何文本，则使用 AppleScript Automator 服务来处理所有文本

Question

我正在使用nslater's wonderful script 计算选定文本块中的单词和字符，但我需要两个增强功能：

1. 即使没有选择文本，脚本也可用。 目前，当我在没有选择的情况下拉出可用服务列表时，服务不存在（当然，这是合乎逻辑的，但增强 #2 会改变一些事情）。

2. 向脚本添加条件行为：如果没有选择文本，则处理所有文本，但如果有选择，则只处理选中的文本文本。

这是 nslater 的脚本，我将其粘贴到 Automator 中（我按照他注释说明中的步骤创建了服务）：

# Word and Character Count service for Mac OS X
#
# Adds a Word and Character Count option to the text selection context menu in all apps
#
# Use Automator.app to create a new service, and then select the Run AppleScript action.
# Paste this code in to the text box, and save as Word and Character Count. Now switch to
# a new app, select some text, and open the context menu to find the new option.

on run {input, parameters}
    tell application "System Events"
        set _appname to name of first process whose frontmost is true
    end tell
    set word_count to count words of (input as string)
    set character_count to count characters of (input as string)
    tell application _appname
        display alert "" & word_count & " words, " & character_count & " characters"
    end tell
    return input
end run

Answer 1

以下 AppleScript 代码将满足您的需求：

tell application "System Events" to set frontApplication to (first application process whose frontmost is true)
set theText to my getCurrentTextContents(frontApplication)
if theText is not "" then
    set wordCount to count words of theText
    set charCount to count characters of theText
    tell application (name of frontApplication) to display alert "" & wordCount & " words, " & charCount & " characters"
end

on getCurrentTextContents(ofApplication)
    tell application "System Events"
        try -- time-out as some UI elements block, notably system sheets
            with timeout of 5 seconds
                set allElements to entire contents of window 1 of ofApplication
            end timeout
        on error
            return ""
        end try

        repeat with UIelement in allElements
            try –– very large element collections can change before looped through
                if focused of UIelement is true then
                    if attribute "AXSelectedTextRange" of UIelement exists then
                        set {x, y} to value of attribute "AXSelectedTextRange" of UIelement
                        if y ≥ x then
                            return value of attribute "AXSelectedText" of UIelement
                        else
                            return value of UIelement
                        end if
                    else
                        return ""
                    end if
                end if
            on error errorMessage
                log errorMessage
                return ""
            end try
        end repeat
        return ""
    end tell
end getCurrentTextContents

如果您想在服务中使用它，则必须将该服务设置为“无输入”——正如 Ken Thomases 正确指出的 in his comment，服务仅在有选择时处理输入。在“无输入”服务的情况下，您实际上是在为脚本创建一个全局（或特定于应用程序，如果您将服务限制为应用程序）启动点。任何其他不会从它所针对的应用程序中窃取焦点的脚本启动器也将提供服务（并且可能会更快 - Automator 服务往往在首次启动时veeerrrrryyyyy sssllllooooowwww）。

还请注意，整个事情通过Accessibility API（GUI 脚本的基础）工作，并且需要访问 API 才能由用户启用 - 或者通过选中“辅助功能”窗格中的“启用辅助设备的访问权限” 系统偏好设置，或者通过做

tell application "System Events" to if not UI elements enabled then
    activate
    set UI elements enabled to true
end if

它还要求目标应用程序在其文本视图中支持 Apple 定义的 Accessibility API（请参阅链接到 above 的文档），并正确执行此操作。 MS Office 应用程序，首先不要（它们使用没有选择属性的非标准视图 - thanks @adayzdone），如果 Adob​​e CS 应用程序也没有，我不会感到惊讶。 Java 和 AIR 应用程序也可能会出现问题。

最后，当我处于 caveat empteor 阶段时，我将添加脚本的速度直接取决于目标应用程序的 UI 层次结构的复杂性。这对于普通应用程序来说不是问题，但对于 WebKit 生成的 Web 视图（即 Safari 等）来说肯定是问题。 – 因为它们将整个 DOM 映射到 UI 元素。尽管在可访问性方面非常值得称赞，但这会导致 UI 层次结构庞大，需要相当长的时间才能遍历。