在excel中计算时差答案

【问题标题】：Calculate time difference in excel在excel中计算时差
【发布时间】：2016-03-24 03:54:25
【问题描述】：

我在 Excel 中有两个日期“2016 年 1 月 2 日 01:56:05”和“2016 年 8 月 3 日 06:21:46”。如何以天和小时的格式计算它们之间的时差？

谢谢！

【问题讨论】：

【解决方案1】：

试试这个包括拼写出来的小时和分钟：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h "" hours, ""m "" minutes""")

请注意，由于m 紧跟在h 之后（忽略引号中的分隔符），它将被解释为分钟而不是月

【讨论】：

【解决方案2】：

我更喜欢使用小数形式的日期。它看起来很麻烦，但我很高兴知道它在做什么。

我通常会在单元格 A3 中设置 A1-A2，然后分别计算组件：

Days: =INT(A3)
Hours: =INT((A3-INT(A3))*24)
Minutes: =INT(((A3*24)-INT(A3*24))*60)

或者，如果您想在一个公式中完成所有操作：

=INT(A3)&" days, "&INT((A3-INT(A3))*24)&" hours, "&INT(((A3*24)-INT(A3*24))*60)&" min"

或不使用 A3

=INT(A1-A2)&" days, "&INT(((A1-A2)-INT(A1-A2))*24)&" hours, "&INT((((A1-A2)*24)-INT((A1-A2)*24))*60)&" min"

这不是最漂亮或最有效的方法，但您可以看到时间是如何计算的。

【讨论】：

【解决方案3】：

假设日期在单元格A1 和A2 中，这将产生带有分钟的答案以及 d:hh:mm 格式。

=INT(A2-A1) & ":" & TEXT(A2-A1,"hh:mm")

如果您不需要分钟，请删除:mm。

如果你想要文字：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h") & " hours"

如果你想要带有分钟的文本：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h"" hours, ""m"" minutes""")

同时使用双引号会“转义”引号本身并允许额外的文本出现在字符串中。正如 Ron 在他的回答中所说，m 后面的 h 以相同的格式字符串表示分钟，因此您可以通过将两者都放在一个格式中来节省额外的 A2-A1 计算。

【讨论】：

它有效，谢谢！但是我如何包括文本部分的会议记录？我尝试了以下但似乎不起作用： =INT(A2-A1) & " days, " & TEXT(A2-A1,"h") & " hours, " & TEXT(A2-A1,"m" ) & "分钟"