构建恢复时如何在 Jenkins 管道中发送通知？

Question

我想在作业恢复时从我的 Jenkins 管道构建中发送通知。这意味着当前构建成功而上一次构建错误（失败、中止等）。

我知道如何发送通知。我认为我的问题归结为如何检查以前构建的状态，但我可能弄错了。

我尝试过“currentBuild.rawBuild.getPreviousBuild()?.getResult()”，但得到异常“org.jenkinsci.plugins.scriptsecurity.sandbox.RejectedAccessException: Scripts not allowed to use method org.jenkinsci.plugins.workflow .support.steps.build.RunWrapper getRawBuild”。如果我关闭沙箱，它应该可以工作。沙盒可以吗？

Answer 1

我找到了另一个可行的解决方案，它不需要您手动跟踪构建结果。虽然，它需要使用脚本元素:(

pipeline {
  agent any
  post {
    success {
      script {
        if (currentBuild.getPreviousBuild() && 
            currentBuild.getPreviousBuild().getResult().toString() != "SUCCESS") {
          echo 'Build is back to normal!'
        }
      }
    }
  }
}

Answer 2

有趣的问题。您可以使用 post{} 部分的“已更改”部分在 Jenkins 声明式管道中执行此操作。但是您需要在作业中将 currentBuild.result 设置为 SUCCESS 或 FAILURE 并在 post 部分进行检查。就 Jenkins 而言，如果不在您的管道中跟踪它，似乎没有一种简单的方法可以获取当前的构建状态（失败、成功等）——除非我错过了一些微妙的东西。这是一个示例，您将在更改部分发送通知，它会检查成功：

pipeline {
    agent any

    parameters {
        string(name: 'FAIL',     defaultValue: 'false', description: 'Whether to fail')
    }

    stages {
        stage('Test') {

            steps {

                script {

                    if(params.FAIL == 'true') {
                        echo "This build will fail"
                        currentBuild.result = 'FAILURE'
                        error("Build has failed")
                    }
                    else {
                        echo "This build is a success"
                        currentBuild.result = 'SUCCESS'
                    }

                }
            }
        }
    }

    post {
        always  {
            echo "Build completed. currentBuild.result = ${currentBuild.result}"
        }

        changed {
            echo 'Build result changed'

            script {
                if(currentBuild.result == 'SUCCESS') {
                    echo 'Build has changed to SUCCESS status'
                }
            }
        }

        failure {
            echo 'Build failed'
        }

        success {
            echo 'Build was a success'
        }
        unstable {
            echo 'Build has gone unstable'
        }
    }
}

--比尔

Answer 3

类似于@Kolky 的回答，这将是“脚本化管道”的 sn-p，您使用“node{ stage1...stage2...etc }”：

    stage('Email') {
        if (currentBuild.getPreviousBuild().getResult().toString() != "SUCCESS") {
            echo 'Build is back to normal!'
            stage('Send build recovered email') {
                mail body: 'My build back to successful',
//                    from: '', replyTo: '',
                        subject: 'My build back to successful',
                        to: 'mymail@server.com'
            }

        }
    }

Answer 4

或者，您可以将脚本逻辑移到管道之外（理想情况下 - 到 Jenkins shared pipeline library 以便可重复使用并保持管道清洁），这样您就不需要 script 块：

def sendNotification(buildStatus) {
  if (buildStatus != 'SUCCESS') {
    // Do nothing - only interested when status becomes GREEN
    return
  }

  mattermostSend "${env.JOB_NAME} has recovered! (<${env.BUILD_URL}|See the build>)"
}

pipeline {
  ...

  post {
    changed {
      sendNotification(currentBuild.currentResult)
    }
  }
}

Answer 5

随附的文档会有所帮助：

Pipeline Ref Card

Answer 6

macg33zr 给出了很好的答案。同时，还有一种更简单的方法可以在管道恢复后在声明性管道中执行某些步骤：post 部分中有一个新的fixed 条件。固定条件部分中的 post 步骤仅在“当前 Pipeline 或阶段的运行成功且前一次运行失败或不稳定的情况下”运行。 （详见Jenkins' declarative pipeline documentation）。

pipeline {
    agent any
    stages {
        stage('Build') {
            steps {
                echo 'Do Something that could fail the pipeline.'
            }
        }
    }
    post { 
        fixed { 
            echo 'Build is back to normal!'
        }
    }
}

如果你想发送通知，有几个 Jenkins 插件，例如 Slack。 Slack 的通知代码如下所示。

pipeline {
    agent any
    stages {
        stage('Build') {
            steps {
                echo 'Do Something that could fail the pipeline.'
            }
        }
    }
    post { 
        fixed { 
            slackSend channel: '#your-slack-target-channel',
                  color: 'good',
                  message: "The build is back to normal. :sweat_smile: The build _${currentBuild.fullDisplayName}_ was successful again.\nGo to pipeline: ${env.BUILD_URL}"
        }
    }
}